(Visual Basic 6.0) SendGrid -- Send Email with Attachment

See more SendGrid Examples

Sends an email with an attachment.

For more information, see https://sendgrid.com/docs/for-developers/sending-email/curl-examples/#sending-a-basic-email-with-attachment

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp
Dim success As Long

' Implements the following CURL command:

' curl --request POST \
'   --url https://api.sendgrid.com/v3/mail/send \
'   --header 'authorization: Bearer YOUR_API_KEY' \
'   --header 'Content-Type: application/json' \
'   --data '{"personalizations": [{"to": [{"email": "recipient@example.com"}]}],"from": {"email": "sender@example.com"},"subject":"Hello, World!","content": [{"type": "text/html","value": "Hey,<br>Please find attachment."}], "attachments": [{"content": "BASE64_ENCODED_CONTENT", "type": "text/plain", "filename": "attachment.txt"}]}'

' Use the following online tool to generate HTTP code from a CURL command
' Convert a cURL Command to HTTP Source Code

' Use this online tool to generate code from sample JSON:
' Generate Code to Create JSON

' The following JSON is sent in the request body.

' {
'   "personalizations": [
'     {
'       "to": [
'         {
'           "email": "recipient@example.com"
'         }
'       ]
'     }
'   ],
'   "from": {
'     "email": "sender@example.com"
'   },
'   "subject": "Hello, World!",
'   "content": [
'     {
'       "type": "text/html",
'       "value": "Hey,<br>Please find attachment."
'     }
'   ],
'   "attachments": [
'     {
'       "content": "BASE64_ENCODED_CONTENT",
'       "type": "text/plain",
'       "filename": "attachment.txt"
'     }
'   ]
' }

Dim json As New ChilkatJsonObject
success = json.UpdateString("personalizations[0].to[0].email","recipient@example.com")
success = json.UpdateString("from.email","sender@example.com")
success = json.UpdateString("subject","Hello, World!")
success = json.UpdateString("content[0].type","text/html")
success = json.UpdateString("content[0].value","Hey,<br>Please find attachment.")

' Load a file to be attached.
Dim bd As New ChilkatBinData
success = bd.LoadFile("qa_data/pdf/hello.pdf")

success = json.UpdateString("attachments[0].content",bd.GetEncoded("base64"))
success = json.UpdateString("attachments[0].type","application/pdf")
success = json.UpdateString("attachments[0].filename","hello.pdf")

http.SetRequestHeader "Content-Type","application/json"
' Adds the "Authorization: Bearer YOUR_API_KEY" header.
http.AuthToken = "YOUR_API_KEY"

Dim resp As ChilkatHttpResponse
Set resp = http.PostJson3("https://api.sendgrid.com/v3/mail/send","application/json",json)
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Dim respStatusCode As Long
respStatusCode = resp.StatusCode
Debug.Print "Response Status Code = " & respStatusCode
If (respStatusCode <> 202) Then
    Debug.Print "Response Header:"
    Debug.Print resp.Header
    Debug.Print "Response Body:"
    Debug.Print resp.BodyStr
    Debug.Print "Failed."

    Exit Sub
End If

Debug.Print "Success."