(Visual Basic 6.0) ScMinidriver - Find and Load Certificate from Smart Card or USB Token

See more ScMinidriver Examples

Demonstrates how to find and load a specific certificate located on a smart card or USB token.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim scmd As New ChilkatScMinidriver

' Reader names (smart card readers or USB tokens) can be discovered
' via List Readers or Find Smart Cards
Dim readerName As String
readerName = "SCM Microsystems Inc. SCR33x USB Smart Card Reader 0"
Dim success As Long
success = scmd.AcquireContext(readerName)
If (success = 0) Then
    Debug.Print scmd.LastErrorText
    Exit Sub
End If

' If successful, the name of the currently inserted smart card is available:
Debug.Print "Card name: " & scmd.CardName

' If desired, perform regular PIN authentication with the smartcard.
' For more details about smart card PIN authentication, see the Smart Card PIN Authentication Example
Dim retval As Long
retval = scmd.PinAuthenticate("user","000000")
If (retval <> 0) Then
    Debug.Print "PIN Authentication failed."
End If

' You can find a cerficate using any of the following certificate parts:
' "subjectDN" -- The full distinguished name of the cert.
' "subjectDN_withTags" -- Same as above, but in a format that includes the subject part tags, such as the "CN=" in "CN=something"
' "subjectCN" -- The common name part (CN) of the certificate's subject.
' "serial" -- The certificate serial number.
' "serial:issuerCN" -- The certificate serial number + the issuer's common name, delimited with a colon char.
' These are the same certificate parts that can be retrieved by listing certificates on the smart card (or USB token).
' See List Certificates on Smart Card Example
Dim certPart As String
certPart = "subjectCN"
Dim partValue As String
partValue = "PIVKey E42D60A759D39147A26E0AF2FB1183C5"

' If the certificate is found, it is loaded into the cert object.
Dim cert As New ChilkatCert
success = scmd.FindCert(certPart,partValue,cert)
If (success = 0) Then
    Debug.Print "Failed to find the certificate."
Else
    Debug.Print "Successfully loaded the cert object from the smart card / USB token."

    ' Note: When successful, the cert object is internally linked to the ScMinidriver object's authenticated session.
    ' The cert object can now be used to sign or do other cryptographic operations that occur on the smart card / USB token.
    ' If your application calls PinDeauthenticate or DeleteContext, the cert will no longer be able to sign on the smart card
    ' because the smart card ScMinidriver session will no longer be authenticated or deleted.
End If

' ...
' ...
' ...

' When finished with operations that required authentication, you may if you wish, deauthenticate the session.
success = scmd.PinDeauthenticate("user")
If (success = 0) Then
    Debug.Print scmd.LastErrorText
End If

' Delete the context when finished with the card.
success = scmd.DeleteContext()
If (success = 0) Then
    Debug.Print scmd.LastErrorText
End If