(Visual Basic 6.0) ScMinidriver - Load Certificate from Smart Card or USB Token by Index

See more ScMinidriver Examples

Demonstrates how to load a certificate located on a smart card or USB token by key container index.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.
Dim scmd As New ChilkatScMinidriver

' Reader names (smart card readers or USB tokens) can be discovered
' via List Readers or Find Smart Cards
Dim readerName As String
readerName = "SCM Microsystems Inc. SCR33x USB Smart Card Reader 0"
Dim success As Long
success = scmd.AcquireContext(readerName)
If (success = 0) Then
    Debug.Print scmd.LastErrorText
    Exit Sub
End If

' If successful, the name of the currently inserted smart card is available:
Debug.Print "Card name: " & scmd.CardName

' If desired, perform regular PIN authentication with the smartcard.
' For more details about smart card PIN authentication, see the Smart Card PIN Authentication Example
Dim retval As Long
retval = scmd.PinAuthenticate("user","000000")
If (retval <> 0) Then
    Debug.Print "PIN Authentication failed."
End If

Dim cert As New ChilkatCert
' We can pass a specific key container index, or -1 to locate the 1st non-empty container containing a certificate and private key.
Dim keyContainerIndex As Long
keyContainerIndex = -1
' keySpec can be "kex" or "sig" to indicate the key-exchange or signature position within the container.
' keySpec can also be "any" to accept either position, with preference given to the "sig" position if both are occupied.
Dim keySpec As String
keySpec = "any"
success = scmd.GetCert(keyContainerIndex,keySpec,cert)
If (success = 0) Then
    Debug.Print "Failed to load the certificate."
Else
    Debug.Print "Successfully loaded the cert object from the smart card / USB token."

    ' Note: When successful, the cert object is internally linked to the ScMinidriver object's authenticated session.
    ' The cert object can now be used to sign or do other cryptographic operations that occur on the smart card / USB token.
    ' If your application calls PinDeauthenticate or DeleteContext, the cert will no longer be able to sign on the smart card
    ' because the smart card ScMinidriver session will no longer be authenticated or deleted.
End If

' ...
' ...
' ...

' When finished with operations that required authentication, you may if you wish, deauthenticate the session.
success = scmd.PinDeauthenticate("user")
If (success = 0) Then
    Debug.Print scmd.LastErrorText
End If

' Delete the context when finished with the card.
success = scmd.DeleteContext()
If (success = 0) Then
    Debug.Print scmd.LastErrorText
End If