Visual Basic 6.0

Create S3 Bucket in a Region

See more Amazon S3 Examples

Demonstrates how to create an S3 bucket in a specified region. This example will create a bucket in the eu-west-2 region. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New ChilkatRest

' Connect to the Amazon AWS REST server.
Dim bTls As Long
bTls = 1
Dim port As Long
port = 443
Dim bAutoReconnect As Long
bAutoReconnect = 1
success = rest.Connect("s3.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials for the REST call.
Dim authAws As New ChilkatAuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"
success = rest.SetAuthAws(authAws)

' We'll send a PUT request having an XML body such as this:
' <CreateBucketConfiguration xmlns="http://s3.amazonaws.com/doc/2006-03-01/"> 
'   <LocationConstraint>BucketRegion</LocationConstraint> 
'   </CreateBucketConfiguration>

' Create the XML body specifying the region as "eu-west-2"
Dim bucketRegion As String
bucketRegion = "eu-west-2"
Dim sbBucketRegion As New ChilkatStringBuilder
success = sbBucketRegion.Append(bucketRegion)

' We only need to specify the LocationConstraint if the bucket's region is NOT us-east-1
Dim xml As New ChilkatXml
If (Not sbBucketRegion.ContentsEqual("us-east-1")) Then
    xml.Tag = "CreateBucketConfiguration"
    success = xml.AddAttribute("xmlns","http://s3.amazonaws.com/doc/2006-03-01/")
    xml.UpdateChildContent "LocationConstraint","eu-west-2"
End If

' --------------------------------------------------------------
' IMPORTANT: To create a bucket in the default us-east-1 region,
' do not add the LocationConstraint.  Adding a LocationConstraint of "us-east-1"
' causes an error "The specified location-constraint is not valid."
' By default, the bucket is created in us-east-1 by sending a PUT with an empty body.
' --------------------------------------------------------------

' Set the bucket name via the HOST header.
' In this case, the bucket name is "chilkateuwest2".
rest.Host = "chilkateuwest2.s3.amazonaws.com"

' Make the call to create the bucket.
Dim responseStr As String
If (Not sbBucketRegion.ContentsEqual("us-east-1")) Then
    responseStr = rest.FullRequestString("PUT","/",xml.GetXml())
Else
    ' If the bucket is to be created in the us-east-1 region (the default region)
    ' just send a PUT with no body.
    responseStr = rest.FullRequestNoBody("PUT","/")
End If

If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

If (rest.ResponseStatusCode <> 200) Then
    Debug.Print "status code = " & rest.ResponseStatusCode
    Dim responseXml As New ChilkatXml
    success = responseXml.LoadXml(responseStr)
    Debug.Print responseXml.GetXml()
    Debug.Print "Failed."
    Exit Sub
End If

Debug.Print "Bucket in the eu-west-2 region created."