(Visual Basic 6.0) RSA Sign Binary Data and Verify (Recover the Original Data)

Demonstrates how to RSA sign binary data and then verify/recover the original data.

Note: This example uses methods introduced in Chilkat v9.5.0.77.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load an RSA private key for signing.
Dim privKey As New PrivateKey
Dim success As Long
success = privKey.LoadEncryptedPemFile("qa_data/pem/rsa_passwd.pem","passwd")
If (success <> 1) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

Dim rsa As New ChilkatRsa
success = rsa.ImportPrivateKeyObj(privKey)

' We have some binary data (in hex) to sign
Dim originalData As String
originalData = "0102030405060708090A"
Dim bd As New ChilkatBinData
success = bd.AppendEncoded(originalData,"hex")

' If successful, the contents of bd are replaced with the RSA signature.
success = rsa.OpenSslSignBd(bd)
If (success <> 1) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

' Show the RSA signature in base64
Debug.Print bd.GetEncoded("base64")

' ------------------------------------------
' Get the public key from the private key
Dim pubKey As PublicKey
Set pubKey = privKey.GetPublicKey()

' Verify the signature and extract the original data.
Dim rsa2 As New ChilkatRsa
success = rsa2.ImportPublicKeyObj(pubKey)

Dim bVerified As Long
bVerified = rsa2.OpenSslVerifyBd(bd)
Debug.Print "signature verified: " & bVerified

' Show the original data:
Debug.Print "original data: " & bd.GetEncoded("hex")