(Visual Basic 6.0) RSA Hash Binary Data and Sign (and Verify)

Demonstrates how to sign the hash of binary data. Also demonstrates how to verify the RSA signature.

Note: This example uses methods introduced in Chilkat v9.5.0.77.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load an RSA private key for signing.
Dim privKey As New PrivateKey
Dim success As Long
success = privKey.LoadEncryptedPemFile("qa_data/pem/rsa_passwd.pem","passwd")
If (success <> 1) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

Dim rsa As New ChilkatRsa
success = rsa.ImportPrivateKeyObj(privKey)

' We have some binary data (in hex) to sign
Dim originalData As String
originalData = "0102030405060708090A"
Dim bdData As New ChilkatBinData
success = bdData.AppendEncoded(originalData,"hex")

' Hash (SHA-256) and sign the hash:
Dim bdSignature As New ChilkatBinData
success = rsa.SignBd(bdData,"sha256",bdSignature)
If (success <> 1) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

' Show the RSA signature in base64
Debug.Print bdSignature.GetEncoded("base64")

' ------------------------------------------
' Get the public key from the private key
Dim pubKey As PublicKey
Set pubKey = privKey.GetPublicKey()

' Verify the signature..
Dim rsa2 As New ChilkatRsa
success = rsa2.ImportPublicKeyObj(pubKey)

Dim bVerified As Long
bVerified = rsa2.VerifyBd(bdData,"sha256",bdSignature)
Debug.Print "signature verified: " & bVerified