(Visual Basic 6.0) Demonstrate RSA Encrypt/Decrypt using BinData

See more RSA Examples

Demonstrates how to RSA encrypt and decrypt data contained in a Chilkat BinData object.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' The RSA public key is used for encryption, and the private key for decryption.

' The public key's role is to make encryption accessible to anyone while ensuring that
' only the private key holder can decrypt the messages.
' The public key is designed to be widely distributed so anyone can use it to encrypt messages
' intended for the owner of the private key.

' Load our 2048-bit RSA public key.
Dim pubKey As New PublicKey
' In all Chilkat methods expecting a path, you pass either absolute or relative paths.
Dim success As Long
success = pubKey.LoadFromFile("rsaKeys/myTestRsaPublic.pem")
If (success = 0) Then
    Debug.Print pubKey.LastErrorText
    Exit Sub
End If

Dim rsa As New ChilkatRsa

' Tell RSA to use the public key.
success = rsa.ImportPublicKeyObj(pubKey)

' RSA encryption is for small amounts of data, on the order of 200 bytes or less.
' The maximum number of bytes that can be RSA encrypted depends
' on the RSA key size and padding scheme (OAEP padding vs PKCS#1 v1.5 padding).
' For specific limits, see: RSA Encryption Maximum Number of Bytes

' Create some binary data to encrypt.
Dim bd As New ChilkatBinData
Dim i As Long
i = 0
For i = 0 To 49
    success = bd.AppendByte(i)
Next

' Show the bytes to be encrypted in hex format:
Debug.Print "To be encrypted: " & bd.GetEncoded("hex")

' To be encrypted: 000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F3031

' RSA encrypt the contents of the bd, replacing the contents with the RSA encrypted data.
success = rsa.EncryptBd(bd,0)

' Now it is encrypted.
Debug.Print "Encrypted size = " & bd.NumBytes
Debug.Print bd.GetEncoded("hex")

' Encrypted size = 256
' 749ED9D0A8767C06C09AD9697F654F86B145F966722F9714902C4175BDBD02E68984ECF111D4D461
' EDB4A8E677D399D19CCA60F35C6DE9972F4262880FE9D77DB75915393E8E7DB80AAB5E383013FAEB
' 60C77D1E6FECC9A7C8426976416C6218FE7DA998EE063CE709E79C240F8625F4A56A0A33AFD63F7A
' BA26F2A692B42E878C53B78602C725FE63FF961A46A2B9D436E5E3D9D64AE3F1D1F5AD5F5B47FCD69
' 447306B77F2FD6D766CCAA1A110A3371586B43DF0D7FFE2220D1B305CF9371AC342F849FB0C90CD99E
' C176928D877FE1C0DE1A7CB6EB824FEC7E1DCF90EF2C6BA9F1DFD3EBFBE89C51AF074DC6AE02E544A78
' 5018C36D3D48B2EF5202AF61AC

' ------------------------------------------------------------------------------------------------------------------------
' Let's decrypt, which requires the matching private key...

' Load the matching 2048-bit RSA private key.
Dim privKey As New PrivateKey
Dim password As String
password = "secret"
success = privKey.LoadAnyFormatFile("rsaKeys/myTestRsaPrivate.pem",password)
If (success = 0) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

' Tell the RSA object to use the private key.
success = rsa.ImportPrivateKeyObj(privKey)

' Decrypt
success = rsa.DecryptBd(bd,1)
If (success = 0) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

' Examine the contents of bd to see if it now contains the unencrypted original data.
Debug.Print "Decrypted: " & bd.GetEncoded("hex")

' Decrypted: 000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F3031