(Visual Basic 6.0) REST through SOCKS Proxy

Demonstrates how to connect through a SOCKS proxy to make REST API calls.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example connects to a REST server through a SOCKS proxy.
' It will connect to the Amazon AWS service for this example.
Dim rest As New ChilkatRest
Dim socket As New ChilkatSocket

' Set the SOCKS proxy domain or IP address, port, and SOCKS version number (4 or 5)
socket.SocksHostname = "192.168.1.100"
socket.SocksPort = 1080
socket.SocksVersion = 5
' Other properties exist for specifying a SOCKS proxy login and password,
' but these are not used in this example.

' Connect through the HTTP proxy to the Amazon AWS server for the S3 service.
Dim bTls As Long
bTls = 1
Dim port As Long
port = 443
Dim maxWaitMs As Long
maxWaitMs = 5000
Dim success As Long
success = socket.Connect("s3.amazonaws.com",port,bTls,maxWaitMs)
If (success <> 1) Then
    Debug.Print "Connect Failure Error Code: " & socket.ConnectFailReason
    Debug.Print socket.LastErrorText
    Exit Sub
End If

' Use the proxied TLS connection:
success = rest.UseConnection(socket,1)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' Provide AWS credentials for the REST call.
Dim authAws As New ChilkatAuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"
success = rest.SetAuthAws(authAws)

' List all buckets for the account...
Dim responseXml As String
responseXml = rest.FullRequestNoBody("GET","/")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Dim xml As New ChilkatXml
success = xml.LoadXml(responseXml)

' Show the full XML returned.
Debug.Print xml.GetXml()

' Iterate over the buckets, showing each bucket name.
success = xml.FindChild2("Buckets")
If (xml.FirstChild2() = 1) Then
    Debug.Print xml.GetChildContent("Name")
    Do While (xml.NextSibling2() = 1)
        Debug.Print xml.GetChildContent("Name")
    Loop
End If

' Move the internal pointer back to the root node.
xml.GetRoot2