(Visual Basic 6.0) Client Certificate in REST

Demonstrates how to use a client certificate with a REST connection.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example shows how to use the Chilkat socket object's connection.
Dim rest As New ChilkatRest
Dim socket As New ChilkatSocket

' Set the certificate to be used for mutual TLS authentication
' (i.e. sets the client-side certificate for two-way TLS authentication)
' Note: There are other ways to set the client certificate using Chilkat.
' For example, on Windows systems, a Chilkat certificate object could be loaded with certificate
' pre-installed (with private key) in a Windows certificate store, and then socket.SetSslClientCert could be called.
Dim success As Long
success = socket.SetSslClientCertPfx("/home/bob/pfxFiles/myClientSideCertWithPrivateKey.pfx","pfxPassword")
If (success <> 1) Then
    Debug.Print socket.LastErrorText
    Exit Sub
End If

' Note: The certificate used for the client-side of TLS mutual authentication
' must have the associated private key available. (.pfx/.p12 files typically store both
' the certificate and associated private key.)

' Establish the connection using the socket object (with client certificate authentication).
Dim bTls As Long
bTls = 1
Dim port As Long
port = 443
Dim maxWaitMs As Long
maxWaitMs = 5000
success = socket.Connect("www.example.com",port,bTls,maxWaitMs)
If (success <> 1) Then
    Debug.Print "Connect Failure Error Code: " & socket.ConnectFailReason
    Debug.Print socket.LastErrorText
    Exit Sub
End If

Dim bAutoReconnect As Long
bAutoReconnect = 1

' Use the connection:
success = rest.UseConnection(socket,bAutoReconnect)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' At this point we are connected and can make REST calls...
' For example..
Dim responseJson As String
responseJson = rest.FullRequestNoBody("GET","/someQuery")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If