Visual Basic 6.0

QuickBooks - Full Update an Employee

See more QuickBooks Examples

Demonstrates how to update any of the writable fields of an existing employee. The example first reads the JSON data for the employee, makes some changes, and then POST's the updated JSON to update the employee. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Get our previously obtained OAuth2 access token, which should contain JSON like this:
' {
'   "expires_in": 3600,
'   "x_refresh_token_expires_in": 8726400,
'   "refresh_token": "L011546037639r ... 3vR2DrbOmg0Sdagw",
'   "access_token": "eyJlbmMiOiJBMTI4Q0 ... oETJEMbeggg",
'   "token_type": "bearer"
' }

Dim jsonToken As New ChilkatJsonObject
success = jsonToken.LoadFile("qa_data/tokens/qb-access-token.json")

Dim rest As New ChilkatRest

' Connect using TLS.
' A single REST object, once connected, can be used for many Quickbooks REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
Dim bAutoReconnect As Long
bAutoReconnect = 1
success = rest.Connect("sandbox-quickbooks.api.intuit.com",443,1,bAutoReconnect)
If (success = 0) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Dim sbAuth As New ChilkatStringBuilder
success = sbAuth.Append("Bearer ")
success = sbAuth.Append(jsonToken.StringOf("access_token"))
rest.Authorization = sbAuth.GetAsString()

success = rest.AddHeader("Accept","application/json")
rest.AllowHeaderFolding = 0

' First get the data for the employee we'll be updating..
' The company ID is 123146096291789
' The employee ID is 58
Dim responseBody As String
responseBody = rest.FullRequestNoBody("GET","/v3/company/123146096291789/employee/58?minorversion=45")
If (rest.LastMethodSuccess = 0) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' We should expect a 200 response if successful.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print "Request Header: "
    Debug.Print rest.LastRequestHeader
    Debug.Print "----"
    Debug.Print "Response StatusCode = " & rest.ResponseStatusCode
    Debug.Print "Response StatusLine: " & rest.ResponseStatusText
    Debug.Print "Response Header:"
    Debug.Print rest.ResponseHeader
    Debug.Print responseBody
    Exit Sub
End If

' Load the JSON response into a JSON object for parsing/updating
Dim json As New ChilkatJsonObject
success = json.Load(responseBody)

' Show the JSON..
json.EmitCompact = 0
Debug.Print json.Emit()
Debug.Print "----"

' The JSON passed in the HTTP POST for updating is the inner content of the Employee
Dim updateJson As New ChilkatJsonObject
success = json.ObjectOf2("Employee",updateJson)

' Add or update the Line1 of the PrimaryAddr.
success = updateJson.UpdateString("PrimaryAddr.Line1","2W 298 Campton Hills Rd.")

' Examine the JSON we'll be sending in the body of the POST.
updateJson.EmitCompact = 0
Debug.Print updateJson.Emit()
Debug.Print "----"

' Now we're going to POST the changes to update the Quickbooks account.
success = rest.ClearAllHeaders()
rest.Authorization = sbAuth.GetAsString()
success = rest.AddHeader("Accept","application/json")
success = rest.AddHeader("Content-Type","application/json")

' The updated JSON is passed as the HTTP request body.
' (The employee ID is specified in the JSON body of the request, and therefore is is not in the path.)
responseBody = rest.FullRequestString("POST","/v3/company/123146096291789/employee?minorversion=45",updateJson.Emit())
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' We should expect a 200 response if successful.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print "Request Header: "
    Debug.Print rest.LastRequestHeader
    Debug.Print "----"
    Debug.Print "Response StatusCode = " & rest.ResponseStatusCode
    Debug.Print "Response StatusLine: " & rest.ResponseStatusText
    Debug.Print "Response Header:"
    Debug.Print rest.ResponseHeader
    Debug.Print responseBody
    Exit Sub
End If

' Load the JSON response into a JSON object to emit in indented form..
success = json.Load(responseBody)
Debug.Print json.Emit()

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

Debug.Print "Success."