Visual Basic 6.0

QuickBooks - Read an Employee (with Error Response)

See more QuickBooks Examples

Demonstrates how to fetch the information for a specific Quickbooks employee, but tries to fetch using an invalid employee id. Shows the error response and how to parse it. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Get our previously obtained OAuth2 access token, which should contain JSON like this:
' {
'   "expires_in": 3600,
'   "x_refresh_token_expires_in": 8726400,
'   "refresh_token": "L011546037639r ... 3vR2DrbOmg0Sdagw",
'   "access_token": "eyJlbmMiOiJBMTI4Q0 ... oETJEMbeggg",
'   "token_type": "bearer"
' }

Dim jsonToken As New ChilkatJsonObject
success = jsonToken.LoadFile("qa_data/tokens/qb-access-token.json")

Dim rest As New ChilkatRest

' Connect using TLS.
' A single REST object, once connected, can be used for many Quickbooks REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
Dim bAutoReconnect As Long
bAutoReconnect = 1
success = rest.Connect("sandbox-quickbooks.api.intuit.com",443,1,bAutoReconnect)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Dim sbAuth As New ChilkatStringBuilder
success = sbAuth.Append("Bearer ")
success = sbAuth.Append(jsonToken.StringOf("access_token"))
rest.Authorization = sbAuth.GetAsString()

success = rest.AddHeader("Accept","application/json")
rest.AllowHeaderFolding = 0

' The company ID is 123146096291789
' The employee ID is 999  (There is no employee with this ID and we should get a 400 response code w/ a response body indicating the error.)
Dim responseBody As String
responseBody = rest.FullRequestNoBody("GET","/v3/company/123146096291789/employee/999?minorversion=45")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' Load the JSON response into a JSON object for parsing.
' A sample JSON response is shown below.
Dim json As New ChilkatJsonObject
success = json.Load(responseBody)
json.EmitCompact = 0
Debug.Print json.Emit()

' A 400 response is what we'd expect if trying to query for a non-existent employee ID
If (rest.ResponseStatusCode <> 400) Then
    Debug.Print "Request Header: "
    Debug.Print rest.LastRequestHeader
    Debug.Print "----"
    Debug.Print "Response StatusCode = " & rest.ResponseStatusCode
    Debug.Print "Response StatusLine: " & rest.ResponseStatusText
    Debug.Print "Response Header:"
    Debug.Print rest.ResponseHeader
    Exit Sub
End If

' If we got here, the response status code was 400..
' Iterate over the errors..
Dim numErrors As Long
numErrors = json.SizeOfArray("Fault.Error")
Dim i As Long
i = 0
Do While i < numErrors

    json.I = i
    Debug.Print "Message: " & json.StringOf("Fault.Error[i].Message")
    Debug.Print "Detail: " & json.StringOf("Fault.Error[i].Detail")
    Debug.Print "code: " & json.StringOf("Fault.Error[i].code")
    Debug.Print "----"
    i = i + 1
Loop

' ------------------------------------------------------
' The JSON error response looks like this:

' {
'   "Fault": {
'     "Error": [
'       {
'         "Message": "Object Not Found",
'         "Detail": "Object Not Found : Something you're trying to use has been made inactive. Check the fields with accounts, customers, items, vendors or employees.",
'         "code": "610",
'         "element": ""
'       }
'     ],
'     "type": "ValidationFault"
'   },
'   "time": "2020-03-07T10:21:19.089-08:00"
' }