Visual Basic 6.0

Quickbooks OAuth2 in a Desktop App

See more QuickBooks Examples

Demonstrates how to get a QuickBooks OAuth2 access token from a desktop application or script. Visual Basic 6.0

Dim success As Long
success = 0

' To further clarify, see OAuth 2.0 Authorization Flow

' ------------------------------------------------------------------------------------------------
' IMPORTANT: You first need to define an App in the Quickbooks Developer Dashboard.
' See How to Create an App in QuickBooks Developer Dashboard
' ------------------------------------------------------------------------------------------------

' This example is for desktop applicatons (it is not for code that runs on a web server).
' You'll need to add a line (or a few lines of code) to popup a web browser that navigates to a URL.

' This is the way to initially obtain the OAuth2 access token.  Afterwards it can be 
' repeatedly refreshed without user interaction, as shown in this example: Refresh Quickbooks OAuth2 Access Token.

Dim oauth2 As New ChilkatOAuth2

' QuickBooks OAuth2 allows for an "http://localhost:<portNumber>/" callback URL for sandbox testing,
' but not for production.

' In production, your applicaton must use your own public web server as an intermediate
' to receive and forward the redirect to localhost.
' See Using Your Web Server as an Intermediary for OAuth2 Redirect to localhost

oauth2.AppCallbackUrl = "https://yourwebserver.com/OAuth2.php"
oauth2.ListenPort = 3017

oauth2.AuthorizationEndpoint = "https://appcenter.intuit.com/connect/oauth2"
oauth2.TokenEndpoint = "https://oauth.platform.intuit.com/oauth2/v1/tokens/bearer"

' Replace these with actual values.
oauth2.ClientId = "QUICKBOOKS-CLIENT-ID"
oauth2.ClientSecret = "QUICKBOOKS-CLIENT-SECRET"
oauth2.UseBasicAuth = 1
oauth2.CodeChallenge = 0

' Indicate the desired access.  Possible scopes that can appear in the list are:
' com.intuit.quickbooks.accounting:  QuickBooks Online API
' com.intuit.quickbooks.payment:  QuickBooks Payments API
' openid:  OpenID Connect processing
' profile:  user's given and family names
' email:  user's email address
' phone:  user's phone number
' address:  user's physical address
oauth2.Scope = "com.intuit.quickbooks.accounting"

' Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
Dim url As String
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess = 0) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

Debug.Print "url = " & url

' Launch the default browser on the system and navigate to the url.
' The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = 0) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

' Wait for the user to approve or deny authorization in the browser.
Dim numMsWaited As Long
numMsWaited = 0
Do While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Loop

' If the browser does not respond within the specified time, AuthFlowState will be:
' 
' 1: Waiting for Redirect – The OAuth2 background thread is waiting for the browser's redirect request.
' 2: Waiting for Final Response – The thread is awaiting the final access token response.
' In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    Debug.Print "No response from the browser!"
    Exit Sub
End If

' Check AuthFlowState to determine if authorization was granted, denied, or failed:
' 
' 3: Success – OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
' 4: Access Denied – OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
' 5: Failure – OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    Debug.Print "OAuth2 failed to complete."
    Debug.Print oauth2.FailureInfo
    Exit Sub
End If

If (oauth2.AuthFlowState = 4) Then
    Debug.Print "OAuth2 authorization was denied."
    Debug.Print oauth2.AccessTokenResponse
    Exit Sub
End If

If (oauth2.AuthFlowState <> 3) Then
    Debug.Print "Unexpected AuthFlowState:" & oauth2.AuthFlowState
    Exit Sub
End If

' Save the full JSON access token response to a file.
Dim sbJson As New ChilkatStringBuilder
success = sbJson.Append(oauth2.AccessTokenResponse)
success = sbJson.WriteFile("qa_data/tokens/qb-access-token.json","utf-8",0)

' The full JSON received looks like this:
' {
'   "expires_in": 3600,
'   "x_refresh_token_expires_in": 8726400,
'   "refresh_token": "L011546037639r ... 3vR2DrbOmg0Sdagw",
'   "access_token": "eyJlbmMiOiJBMTI4Q0 ... oETJEMbeggg",
'   "token_type": "bearer"
' }

Debug.Print "OAuth2 authorization granted!"
Debug.Print "Access Token = " & oauth2.AccessToken

' Get the realmId if needed...
' See About the QuickBooks REST API Realm ID, also known as Company ID
Dim realmId As String
realmId = oauth2.GetRedirectRequestParam("realmId")
If (oauth2.LastMethodSuccess = 1) Then
    Debug.Print "realmId: " & realmId
Else
    Debug.Print "No realmId was provided."
End If