Visual Basic 6.0

POP3: Download Most Recent Email (method 1)

How to ready the N most recent email from a POP3 server.

The POP3 protocol does not provide the ability to request the most recent email, nor does it provide the ability to download email based on read/unread status or any other criteria. The design principle behind POP3 is that it is a temporary holding store for incoming email and email clients or other applications will transfer email from the POP3 server to a local persistent store where it will be managed. Therefore, POP3 does not provide sophisticated functionality (as opposed to IMAP which has the opposite design philosophy: that email is maintained and organized on the server).

This example shows one possible way to retrieve the N most recent emails from a POP3 server. It downloads the headers into a bundle object, then sorts the bundle by date, and finally retrieves the most recent emails by UIDL.

Another alternative is to download the UIDL list and then assume that the 1st N UIDLs are the most recent.

Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The mailman object is used for receiving (POP3) 
' and sending (SMTP) email.
Dim mailman As New ChilkatMailMan

' Set the POP3 server's hostname
mailman.MailHost = "pop.example.com"

' Set the POP3 login/password.
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

' Read mail headers and one line of the body.
Dim bundle As New ChilkatEmailBundle
Dim keepOnServer As Long
keepOnServer = 1
Dim headersOnly As Long
headersOnly = 1
Dim numBodyLines As Long
numBodyLines = 1
success = mailman.FetchAll(keepOnServer,headersOnly,numBodyLines,bundle)
If (success = 0) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

' Sort the bundle by date
Dim ascending As Long
ascending = 0
bundle.SortByDate ascending

' Get the 10 most recent UIDLs
Dim stUidls As New ChilkatStringTable
Dim n As Long
n = bundle.MessageCount
If (n > 10) Then
    n = 10
End If

Dim email As New ChilkatEmail
Dim i As Long
i = 0
Do While i < n
    success = bundle.EmailAt(i,email)
    success = stUidls.Append(email.Uidl)
    i = i + 1
Loop

' Download in full the 10 most recent emails:
Dim bundle2 As New ChilkatEmailBundle
headersOnly = 0
' numBodyLines is ignored if we're fetching the full emails.
success = mailman.FetchUidlSet(stUidls,headersOnly,numBodyLines,bundle2)
If (success = 0) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

i = 0
Do While i < bundle2.MessageCount
    success = bundle2.EmailAt(i,email)

    Debug.Print email.From
    Debug.Print email.Subject
    Debug.Print "----"

    i = i + 1
Loop