Visual Basic 6.0 Requires Chilkat v11.0.0+

POP3 over Multiple Hop SSH

Demonstrates how to read POP3 email (using TCP or TLS) tunneled through mulitple-hop SSH. The scheme looks like this:

Application => ServerSSH1 => ServerSSH2 => POP3Server

Visual Basic 6.0

Dim success As Long
success = 0

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim ssh1 As New ChilkatSsh

'  Connect directly to the 1st SSH server.
success = ssh1.Connect("serverssh1.com",22)
If (success = 0) Then
    Debug.Print ssh1.LastErrorText
    Exit Sub
End If

'  Authenticate using login/password:
success = ssh1.AuthenticatePw("ssh1Login","ssh1Password")
If (success = 0) Then
    Debug.Print ssh1.LastErrorText
    Exit Sub
End If

'  Connect through the 1st SSH connection to reach a 2nd SSH server.
'  Note: Any number of SSH connections may be simultaneously tunneled through a single
'  existing SSH connection.
Dim ssh2 As New ChilkatSsh
success = ssh2.ConnectThroughSsh(ssh1,"serverssh2.com",22)
If (success = 0) Then
    Debug.Print ssh2.LastErrorText
    Exit Sub
End If

'  Authenticate with ssh2...
success = ssh2.AuthenticatePw("ssh2Login","ssh2Password")
If (success = 0) Then
    Debug.Print ssh2.LastErrorText
    Exit Sub
End If

Dim mailman As New ChilkatMailMan

'  Tell the mailman object to connect to the POP3 server though the ssh2 tunnel (which itself is routed through ssh1).
'  The connection looks like this:  Application => ServerSSH1 => ServerSSH2 => POP3Server
success = mailman.UseSsh(ssh2)
If (success = 0) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

'  Set the POP3 server's hostname
mailman.MailHost = "pop.example.com"

'  Set the POP3 login/password.
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

'  Establish the POP3 connection through the ssh2 tunnel.
success = mailman.Pop3BeginSession()
If (success = 0) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

'  Get the number of messages in the mailbox.
Dim numMessages As Long
numMessages = mailman.GetMailboxCount()

Dim email As New ChilkatEmail
Dim i As Long
i = 1
Do While i <= numMessages
    '  Fetch by the message number (not by the UIDL)
    success = mailman.FetchOne(0,0,i,email)
    If (success = 0) Then
        Debug.Print mailman.LastErrorText
        Exit Sub
    End If

    Debug.Print email.From & ": " & email.Subject & vbLf

    i = i + 1
Loop

'  Close the connection with the POP3 server.  (This closes the tunnel through ssh2)
'  The connection with ssh2 is still alive, and may be used for more connections.
success = mailman.Pop3EndSession()

'  Close the connection with ssh2.  (This closes the the tunnel through ssh1.)
'  The connection with ssh1 is still alive, and may be used for more connections.

ssh2.Disconnect 

ssh1.Disconnect