Visual Basic 6.0 Requires Chilkat v11.0.0+

RSASSA-PSS Sign String to Create Base64 PCKS7 Signature

See more Digital Signatures Examples

Signs a string to create a PKCS7 signature in the base64 encoding. The signature algorithm is RSASSA-PSS with SHA256. Visual Basic 6.0

Dim success As Long
success = 0

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim crypt As New ChilkatCrypt2

'  Get a digital certificate with private key from a .pfx
'  (Chilkat has many different ways to provide a cert + private key for siging.
'  Using a PFX is just one possible option.)
Dim pfx As New ChilkatPfx
success = pfx.LoadPfxFile("qa_data/rsassa-pss/privatekey.pfx","PFX_PASSWORD")
If (success = 0) Then
    Debug.Print pfx.LastErrorText
    Exit Sub
End If

'  Get the certificate to be used for signing.
'  (The typical case for a PFX is that it contains a cert with an associated private key,
'  as well as other certificates in the chain of authentication.  The cert with the private
'  key should be in the first position at index 0.)

Dim cert As New ChilkatCert
success = pfx.CertAt(0,cert)
If (success = 0) Then
    Debug.Print pfx.LastErrorText
    Exit Sub
End If

success = crypt.SetSigningCert(cert)

'  Indicate that RSASSA-PSS with SHA256 should be used.
crypt.SigningAlg = "pss"
crypt.HashAlgorithm = "sha256"

crypt.EncodingMode = "base64"

'  Sign a string and return the base64 PKCS7 detached signature
Dim originalText As String
originalText = "This is a test"
Dim pkcs7sig As String
pkcs7sig = crypt.SignStringENC(originalText)
Debug.Print "Detached Signature:"
Debug.Print pkcs7sig

'  This signature looks like this:
'  MIIG5wYJKoZIhvcNAQcCoIIG2DCCBtQCAQExDzANBgl .. YToLqEwTdU87ox5g7rvw==

'  The ASN.1 of the signature can be examined by browsing to https://lapo.it/asn1js/ ,
'  then copy-and-paste the Base64 signature into the form and decode..

'  The signature can be verified against the original data like this:
success = crypt.VerifyStringENC(originalText,pkcs7sig)
Debug.Print "Signature verified: " & success
success = crypt.VerifyStringENC("Not the original text",pkcs7sig)
Debug.Print "Signature verified: " & success

'  Now we'll create an opaque signature (the opposite of a detached signature). 
'  An opaque signature is a PKCS7 message that contains both the original data and
'  the signature.  The verification process extracts the original data.
Dim opaqueSig As String
opaqueSig = crypt.OpaqueSignStringENC(originalText)
Debug.Print "Opaque Signature:"
Debug.Print opaqueSig

'  The ASN.1 of the signature can be examined by browsing to https://lapo.it/asn1js/ ,
'  then copy-and-paste the Base64 signature into the form and decode..

'  We can verify and extract the original data:
Dim origTxt As String
origTxt = crypt.OpaqueVerifyStringENC(opaqueSig)
If (crypt.LastMethodSuccess <> 1) Then
    Debug.Print "Signature verification failed."
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Debug.Print "Signature verified."
Debug.Print "Extracted text:" & origTxt