(Visual Basic 6.0) PKCS11 Import an Existing AES Key onto the HSM

See more PKCS11 Examples

Demonstrates how to import an existing AES symmetric encrytion key onto the smartcard/token. The imported AES key is a session object, and only exists for the duration of the PKCS11 session. (AES keys are typically used for wrapping/unwrapping RSA and EC keys.)

Note: This example requires Chilkat v9.5.0.96 or later.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: Chilkat's PKCS11 implementation runs on Windows, Linux, Mac OS X, and other supported operating systems.

Dim pkcs11 As New ChilkatPkcs11

' Use the PKCS11 driver (.dll, .so, .dylib) for your particular HSM.
' (The format of the path will change with the operating system.  Obviously, "C:/" is not used on non-Windows systems.
pkcs11.SharedLibPath = "C:/Program Files (x86)/Gemalto/IDGo 800 PKCS#11/IDPrimePKCS1164.dll"

' Establish a logged-on session.
Dim pin As String
pin = "0000"
Dim userType As Long
userType = 1
Dim success As Long
success = pkcs11.QuickSession(userType,pin)
If (success = 0) Then
    Debug.Print pkcs11.LastErrorText
    Exit Sub
End If

' Generate a 256-bit AES key.
' (32 bytes is 256 bits)
' Append 32 bytes of random data in the base64 encoding.
Dim sbAesKey As New ChilkatStringBuilder
success = sbAesKey.AppendRandom(32,"base64")

Dim attrs As New ChilkatJsonObject
' Specify the type of object, and the type of key.
success = attrs.UpdateString("class","CKO_SECRET_KEY")
success = attrs.UpdateString("key_type","CKK_AES")
' Add an optional label if desired.
success = attrs.UpdateString("label","My AES wrapping/unwrapping key")
' Allow the key to be use for wrapping and unwrapping operations.
success = attrs.UpdateBool("wrap",1)
success = attrs.UpdateBool("unwrap",1)

' Provide the AES key material.
success = attrs.UpdateString("value",sbAesKey.GetAsString())

' Create the object (i.e. create the AES key with the given key material.)
' Returns the PKCS11 object handle of the created AES session key.
Dim objHandle As Long
objHandle = pkcs11.CreatePkcs11Object(attrs)
If (objHandle = 0) Then
    Debug.Print pkcs11.LastErrorText
    Debug.Print "Failed."
Else
    Debug.Print "PKCS11 object handle = " & objHandle
    Debug.Print "Successfully created a 256-bit AES session key."
End If

' Typically, you would do other things in the PKCS11 session that use the handle of AES key we just created.
' ...
' ...

success = pkcs11.Logout()
success = pkcs11.CloseSession()