Visual Basic 6.0 Requires Chilkat v11.0.0+

Install PFX Certificates and Private Keys to Windows

See more PFX/P12 Examples

Demonstrates how to install the certificates and private keys contained in a PFX to the Windows certificate stores. Visual Basic 6.0

Dim success As Long
success = 0

Dim pfx As New ChilkatPfx

success = pfx.LoadPfxFile("qa_data/pfx/test_secret.pfx","secret")
If (success = 0) Then
    Debug.Print pfx.LastErrorText
    Exit Sub
End If

'  See the online reference documentation for more information about the ImportToWindows method.

'  Mark imported privae keys as exportable.
Dim exportable As Long
exportable = 1

'  If userProtected is 1, the user is to be notified through a dialog box or other method when certain attempts to use this key are made. 
Dim userProtected As Long
userProtected = 0

'  If machineKeyset is 1, the private keys are stored under the local computer and not under the current user. 
Dim machineKeyset As Long
machineKeyset = 0

'  If allowOverwriteKey is 1, allow overwrite of the existing key. 
Dim allowOverwriteKey As Long
allowOverwriteKey = 0

'  If allowExport is 1, then the imported key can later be exported back to a PFX.
'  (It also allows for applications to directly access the private key material.)
Dim allowExport As Long
allowExport = 1

'  Indicate where to import types of certs.
Dim leafStore As String
leafStore = "My"
Dim intermediateStore As String
intermediateStore = "CertificationAuthority"
Dim rootStore As String
rootStore = "AuthRoot"

success = pfx.ImportToWindows(exportable,userProtected,machineKeyset,allowOverwriteKey,allowExport,leafStore,intermediateStore,rootStore,"")
If (success = 0) Then
    Debug.Print pfx.LastErrorText
    Exit Sub
End If

'  Show information about the certificates imported
Dim json As New ChilkatJsonObject
pfx.GetLastJsonData json

json.EmitCompact = 0
Debug.Print json.Emit()

'  Sample output:

'  {
'    "exportable": true,
'    "userProtected": false,
'    "machineKeyset": false,
'    "allowOverwriteKey": false,
'    "allowExport": true,
'    "key": [
'      {
'        "name": "{F09B755A-1E90-444D-9851-02B86CA14961}",
'        "storageProvider": "Microsoft Software Key Storage Provider"
'      }
'    ],
'    "cert": [
'      {
'        "DN": "...",
'        "type": "intermediate",
'        "storeName": "CertificationAuthority",
'        "imported": true
'      },
'      {
'        "DN": "...",
'        "type": "root",
'        "storeName": "AuthRoot",
'        "imported": true
'      },
'      {
'        "DN": "....",
'        "type": "leaf",
'        "storeName": "My",
'        "keyContainer": "{345D4EAD-B8DD-4150-9A1F-4BC6437E77A2}",
'        "machineKeyset": true,
'        "imported": true
'      }
'    ]
'  }

Debug.Print "Success."