(Visual Basic 6.0) Peoplevox WMS Authentication

Provides an example of a call to the Peoplevox WMS Authenticate using SOAP 1.1.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Long

' Sends a POST that looks like this:

' 	POST /PEOPLEVOX_CLIENT_ID/resources/integrationservicev4.asmx HTTP/1.1
' 	Content-Type: text/xml;charset=UTF-8
' 	SOAPAction: http://www.peoplevox.net/Authenticate
' 	Content-Length: (automatically computed and added by Chilkat)
' 	Host: qac.peoplevox.net
' 
' 	<?xml version="1.0" encoding="utf-8"?>
' 	<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:peop="http://www.peoplevox.net/">
' 	   <soapenv:Header/>
' 	   <soapenv:Body>
' 	      <peop:Authenticate>
' 	         <peop:clientId>PEOPLEVOX_CLIENT_ID</peop:clientId>
' 	         <peop:username>PEOPLEVOX_USERNAME</peop:username>
' 	         <peop:password>PEOPLEVOX_BASE64_PASSWORD</peop:password>
' 	      </peop:Authenticate>
' 	   </soapenv:Body>
' 	</soapenv:Envelope>
' 

Dim sbSoapXml As New ChilkatStringBuilder
success = sbSoapXml.Append("<?xml version=""1.0"" encoding=""utf-8""?>")
success = sbSoapXml.Append("<soapenv:Envelope xmlns:soapenv=""http://schemas.xmlsoap.org/soap/envelope/"" xmlns:peop=""http://www.peoplevox.net/"">")
success = sbSoapXml.Append("   <soapenv:Header/>")
success = sbSoapXml.Append("   <soapenv:Body>")
success = sbSoapXml.Append("      <peop:Authenticate>")
success = sbSoapXml.Append("         <peop:clientId>PEOPLEVOX_CLIENT_ID</peop:clientId>")
success = sbSoapXml.Append("         <peop:username>PEOPLEVOX_USERNAME</peop:username>")
success = sbSoapXml.Append("         <peop:password>PEOPLEVOX_BASE64_PASSWORD</peop:password>")
success = sbSoapXml.Append("      </peop:Authenticate>")
success = sbSoapXml.Append("   </soapenv:Body>")
success = sbSoapXml.Append("</soapenv:Envelope>")

' Base64 encode the password and update the SOAP XML.
Dim crypt As New ChilkatCrypt2
Dim passwordBase64 As String
passwordBase64 = crypt.EncodeString("PEOPLEVOX_PASSWORD","utf-8","base64")
Dim numReplacements As Long
numReplacements = sbSoapXml.Replace("PEOPLEVOX_BASE64_PASSWORD",passwordBase64)

Dim req As New ChilkatHttpRequest
req.HttpVerb = "POST"
req.SendCharset = 1
req.Charset = "utf-8"
req.AddHeader "Content-Type","text/xml"
req.AddHeader "SOAPAction","http://www.peoplevox.net/Authenticate"
req.Path = "/PEOPLEVOX_CLIENT_ID/resources/integrationservicev4.asmx"
success = req.LoadBodyFromString(sbSoapXml.GetAsString(),"utf-8")

Dim http As New ChilkatHttp
http.FollowRedirects = 1

Dim resp As ChilkatHttpResponse
Set resp = http.SynchronousRequest("qac.peoplevox.net",443,1,req)
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' We should expect a 200 response if successful.
If (resp.StatusCode <> 200) Then
    Debug.Print "Response StatusCode = " & resp.StatusCode
    Debug.Print "Response StatusLine: " & resp.StatusLine
    Debug.Print "Response Header:"
    Debug.Print resp.Header
    Exit Sub
End If

' A successful response returns this XML:

' <?xml version="1.0" encoding="utf-8" ?>
' <soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
'     <soap:Body>
'         <AuthenticateResponse xmlns="http://www.peoplevox.net/">
'             <AuthenticateResult>
'                 <ResponseId>0</ResponseId>
'                 <TotalCount>1</TotalCount>
'                 <Detail>PEOPLEVOX_CLIENT_ID,7fe13431-c67f-4d52-bcfd-b60fbfa3b0ca</Detail>
'                 <Statuses />
'                 <ImportingQueueId>0</ImportingQueueId>
'                 <SalesOrdersToDespatchIds />
'             </AuthenticateResult>
'         </AuthenticateResponse>
'     </soap:Body>
' </soap:Envelope>
' 

Dim xmlResponse As New ChilkatXml
success = xmlResponse.LoadXml(resp.BodyStr)
Debug.Print xmlResponse.GetXml()

' Show how to get the Detail, which must be the ClientId,SessionId
Dim detail As String
detail = xmlResponse.ChilkatPath("soap:Body|AuthenticateResponse|AuthenticateResult|Detail|*")
Debug.Print "Detail = " & detail