(Visual Basic 6.0) Convert Let's Encrypt PEM Files to a PFX

Demonstrates how to convert the .pem files provided by Let's Encrypt to a single PFX.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Let's Encrypt provides four .pem files
' 1. fullchain.pem
' 2. privkey.pem
' 3. cert.pem
' 4. chain.pem

' The cert.pem and chain.pem are redundant. 
' The fullchain.pem is composed of the cert.pem and chain.pem.

' To convert the PEM's to a single .pfx, we don't need the redundant data.
' The privkey.pem and fullchain.pem provide the required data.
' We can ignore cert.pem and chain.pem (because those certs are already found in fullchain.pem).

' We need a single .pem file that contains both the private key, the cert,
' and the certs in the chain of authentication.
' Let's combine priveky.pem and fullchain.pem into a single .pem

Dim sbPem As New ChilkatStringBuilder
Dim success As Long
success = sbPem.LoadFile("qa_data/pem/lets_encrypt/privkey.pem","utf-8")
If (success = 0) Then
    Debug.Print "Failed to load privkey.pem"
    Exit Sub
End If

' To be safe, append a blank line..
success = sbPem.AppendLine("",0)

Dim sbFullChainPem As New ChilkatStringBuilder
success = sbFullChainPem.LoadFile("qa_data/pem/lets_encrypt/fullchain.pem","utf-8")
If (success = 0) Then
    Debug.Print "Failed to load fullchain.pem"
    Exit Sub
End If

' Append the full cert chain PEM to the private key PEM.
success = sbPem.AppendSb(sbFullChainPem)

' Load the combined PEM into a Chilkat PFX object.
Dim pfx As New ChilkatPfx
success = pfx.LoadPem(sbPem.GetAsString(),"no password required")
If (success = 0) Then
    Debug.Print pfx.LastErrorText
    Exit Sub
End If

' Write the PFX w/ a password.
Dim pfxPassword As String
pfxPassword = "secret"
success = pfx.ToFile(pfxPassword,"qa_output/sample.pfx")
If (success = 0) Then
    Debug.Print pfx.LastErrorText
    Exit Sub
End If

Debug.Print "Success!"