Sample code for 30+ languages & platforms
Visual Basic 6.0 Requires Chilkat v11.0.0+

PayPal: Update the price on a reusable payment link

See more PayPal Examples

Retrieve the simple USD inspection link from the create example. Check its item and currency, retain its configuration, and replace the price with USD 95. PUT sends the complete editable definition.

PayPal documentation

Chilkat Visual Basic 6.0 Downloads

Visual Basic 6.0
Dim success As Long
success = 0

'  See Unlock Chilkat before making requests.
'  For the merchant's internal backoffice application. Load the sandbox token
'  from the merchant's credential store. Keep it out of publicly distributed apps.
'  See Get a PayPal access token.
Dim http As New ChilkatHttp
http.AuthToken = "SANDBOX_ACCESS_TOKEN"
Dim resp As New ChilkatHttpResponse

success = http.SetUrlVar("id","PAYMENT_RESOURCE_ID")

success = http.HttpNoBody("GET","https://api-m.sandbox.paypal.com/v1/checkout/payment-resources/{$id}",resp)
If (success <> 1) Then
    Debug.Print "No HTTP response: " & http.LastErrorText
    Exit Sub
End If

If ((resp.StatusCode < 200) Or (resp.StatusCode >= 300)) Then
    Dim errorInfo As New ChilkatJsonObject
    success = errorInfo.Load(resp.BodyStr)
    Debug.Print "HTTP " & resp.StatusCode & " " & errorInfo.StringOf("name") & " " & errorInfo.StringOf("details[0].issue")
    Debug.Print "PayPal debug ID: " & errorInfo.StringOf("debug_id")
    Exit Sub
End If

Dim result As New ChilkatJsonObject
Dim parsedResult As Long
parsedResult = result.Load(resp.BodyStr)
If (parsedResult <> 1) Then
    Debug.Print "Expected a JSON response; HTTP " & resp.StatusCode
    Exit Sub
End If

If ((result.SizeOfArray("line_items") <> 1) Or (result.StringOfEquals("line_items[0].name","Annual inspection",1) <> 1) Or (result.StringOfEquals("line_items[0].unit_amount.currency_code","USD",1) <> 1)) Then
    Debug.Print "Select the USD inspection link from your catalog."
    Exit Sub
End If

'  Preserve line items, taxes, shipping and checkout settings from the retrieved link.
'  Remove the resource metadata PayPal added to the GET response.
If (result.HasMember("id") = 1) Then
    success = result.Delete("id")
End If

If (result.HasMember("create_time") = 1) Then
    success = result.Delete("create_time")
End If

If (result.HasMember("update_time") = 1) Then
    success = result.Delete("update_time")
End If

If (result.HasMember("status") = 1) Then
    success = result.Delete("status")
End If

If (result.HasMember("links") = 1) Then
    success = result.Delete("links")
End If

If (result.HasMember("payment_link") = 1) Then
    success = result.Delete("payment_link")
End If

success = result.UpdateString("line_items[0].unit_amount.value","95.00")
success = http.HttpJson("PUT","https://api-m.sandbox.paypal.com/v1/checkout/payment-resources/{$id}",result,"application/json",resp)
If (success <> 1) Then
    Debug.Print "No HTTP response: " & http.LastErrorText
    Exit Sub
End If

If ((resp.StatusCode < 200) Or (resp.StatusCode >= 300)) Then
    Dim updateError As New ChilkatJsonObject
    success = updateError.Load(resp.BodyStr)
    Debug.Print "HTTP " & resp.StatusCode & " " & updateError.StringOf("name") & " " & updateError.StringOf("details[0].issue")
    Debug.Print "PayPal debug ID: " & updateError.StringOf("debug_id")
    Exit Sub
End If

Debug.Print "The inspection price is now USD 95.00."