Visual Basic 6.0 Requires Chilkat v11.0.0+
Visual Basic 6.0
PayPal: Get authorization details
See more PayPal Examples
Use the authorization ID returned when authorizing an order. Read its status and expiration before scheduling capture; do not substitute the checkout order ID.
Chilkat Visual Basic 6.0 Downloads
Dim success As Long
success = 0
' See Unlock Chilkat before making requests.
' For the merchant's internal backoffice application. Load the sandbox token
' from the merchant's credential store. Keep it out of publicly distributed apps.
' See Get a PayPal access token.
Dim http As New ChilkatHttp
http.AuthToken = "SANDBOX_ACCESS_TOKEN"
Dim resp As New ChilkatHttpResponse
' The authorization ID comes from purchase_units[].payments.authorizations[], not the
' top-level order ID.
success = http.SetUrlVar("id","AUTHORIZATION_ID")
success = http.HttpNoBody("GET","https://api-m.sandbox.paypal.com/v2/payments/authorizations/{$id}",resp)
If (success <> 1) Then
Debug.Print "No HTTP response: " & http.LastErrorText
Exit Sub
End If
If ((resp.StatusCode < 200) Or (resp.StatusCode >= 300)) Then
Dim errorInfo As New ChilkatJsonObject
success = errorInfo.Load(resp.BodyStr)
Debug.Print "HTTP " & resp.StatusCode & " " & errorInfo.StringOf("name") & " " & errorInfo.StringOf("details[0].issue")
Debug.Print "PayPal debug ID: " & errorInfo.StringOf("debug_id")
Exit Sub
End If
Dim result As New ChilkatJsonObject
Dim parsed As Long
parsed = result.Load(resp.BodyStr)
If (parsed <> 1) Then
Debug.Print "Expected a JSON response; HTTP " & resp.StatusCode
Exit Sub
End If
Debug.Print "ID: " & result.StringOf("id")
Debug.Print "Status: " & result.StringOf("status")
Debug.Print "Amount: " & result.StringOf("amount.value")
Debug.Print "Currency: " & result.StringOf("amount.currency_code")
Debug.Print "Expires: " & result.StringOf("expiration_time")