(Visual Basic 6.0) Sign Manifest File to Generate a Passbook .pkpass file

Demonstrates how to create a Passbook .pkpass archive by creating a signature of a manifest file and then zipping to a .pkpass archive.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' Note: Requires Chilkat v9.5.0.75 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' ---------------------------------------------------------------------------------------------
' Note: Chilkat also has the capability to do everything in-memory (no files would be involved).  
' See this example:  Sign Manifest File to Generate a Passbook .pkpass in Memory
' ---------------------------------------------------------------------------------------------

' First create the manifest.json
Dim success As Long
Dim manifest As New ChilkatJsonObject
Dim crypt As New ChilkatCrypt2

Dim zip As New ChilkatZip
success = zip.NewZip("qa_data/p7s/pass-wallet/example.pkpass")
' Set the AppendFromDir property to prevent that relative paths from being stored in the .pkpass archive.
zip.AppendFromDir = "qa_data/p7s/pass-wallet/"

crypt.HashAlgorithm = "sha1"
' Return hashes as lowercase hex.
crypt.EncodingMode = "hexlower"

Dim fileHash As String
Dim filePath As String
filePath = "qa_data/p7s/pass-wallet/icon.png"
fileHash = crypt.HashFileENC(filePath)
success = zip.AppendOneFileOrDir("icon.png",0)
success = manifest.UpdateString("""icon.png""",fileHash)

filePath = "qa_data/p7s/pass-wallet/icon@2x.png"
fileHash = crypt.HashFileENC(filePath)
success = zip.AppendOneFileOrDir("icon@2x.png",0)
success = manifest.UpdateString("""icon@2x.png""",fileHash)

filePath = "qa_data/p7s/pass-wallet/logo.png"
fileHash = crypt.HashFileENC(filePath)
success = zip.AppendOneFileOrDir("logo.png",0)
success = manifest.UpdateString("""logo.png""",fileHash)

filePath = "qa_data/p7s/pass-wallet/logo@2x.png"
fileHash = crypt.HashFileENC(filePath)
success = zip.AppendOneFileOrDir("logo@2x.png",0)
success = manifest.UpdateString("""logo@2x.png""",fileHash)

filePath = "qa_data/p7s/pass-wallet/pass.json"
fileHash = crypt.HashFileENC(filePath)
success = zip.AppendOneFileOrDir("pass.json",0)
success = manifest.UpdateString("""pass.json""",fileHash)

Dim sbJson As New ChilkatStringBuilder
success = manifest.EmitSb(sbJson)
Dim manifestPath As String
manifestPath = "qa_data/p7s/pass-wallet/manifest.json"
success = sbJson.WriteFile(manifestPath,"utf-8",0)
success = zip.AppendOneFileOrDir("manifest.json",0)

' Make sure we have the Apple WWDR intermediate certificate available for 
' the cert chain in the signature.
Dim certVault As New ChilkatXmlCertVault
Dim appleWwdrCert As New ChilkatCert
success = appleWwdrCert.LoadByCommonName("Apple Worldwide Developer Relations Certification Authority")
If (success <> 1) Then
    Debug.Print "The Apple WWDR intermediate certificate is not installed."
    Debug.Print "It is available at https://developer.apple.com/certificationauthority/AppleWWDRCA.cer"
    Debug.Print "You may alternatively load the .cer like this..."
    success = appleWwdrCert.LoadFromFile("qa_data/certs/AppleWWDRCA.cer")
    If (success <> 1) Then
        Debug.Print appleWwdrCert.LastErrorText
        Exit Sub
    End If

End If

success = certVault.AddCert(appleWwdrCert)
success = crypt.UseCertVault(certVault)

' Use a digital certificate and private key from a PFX file (.pfx or .p12).
Dim pfxPath As String
pfxPath = "qa_data/pfx/cert_test123.pfx"
Dim pfxPassword As String
pfxPassword = "test123"

Dim cert As New ChilkatCert
success = cert.LoadPfxFile(pfxPath,pfxPassword)
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Provide the signing cert (with associated private key).
success = crypt.SetSigningCert(cert)
If (success <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' Specify the signed attributes to be included.
' (These attributes appear to not be necessary, but we're including
' them just in case they become necessary in the future.)
Dim jsonSignedAttrs As New ChilkatJsonObject
success = jsonSignedAttrs.UpdateInt("contentType",1)
success = jsonSignedAttrs.UpdateInt("signingTime",1)
crypt.SigningAttributes = jsonSignedAttrs.Emit()

' Sign the manifest JSON file to produce a file named "signature".
Dim sigPath As String
sigPath = "qa_data/p7s/pass-wallet/signature"

' Create the "signature" file.
success = crypt.CreateP7S(manifestPath,sigPath)
If (success = 0) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

success = zip.AppendOneFileOrDir("signature",0)

' ---------------------------------------------------------------------------------------------
' Note: Chilkat also has the capability to do everything in-memory (no files would be involved).  
' If this is of interest, please send email to support@chilkatsoft.com
' ---------------------------------------------------------------------------------------------

' Create the .pkipass archive (which is a .zip archive containing the required files).
success = zip.WriteZipAndClose()
If (success <> 1) Then
    Debug.Print zip.LastErrorText
    Exit Sub
End If

Debug.Print "Success."