Visual Basic 6.0
Visual Basic 6.0
palena.sii.cl getSeed SOAP Request
See more SII Chile Examples
Demonstrates how to call getSeed SOAP request at palena.sii.clChilkat Visual Basic 6.0 Downloads
Dim success As Long
success = 0
Dim http As New ChilkatHttp
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.
Dim responseStatusCode As Long
http.UncommonOptions = "AllowEmptyHeaders"
http.SetRequestHeader "SOAPAction",""
' The endpoint for this soap service is:
Dim endPoint As String
endPoint = "https://palena.sii.cl/DTEWS/CrSeed.jws"
' Send the following SOAP XML
' <soapenv:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:def="http://DefaultNamespace">
' <soapenv:Header/>
' <soapenv:Body>
' <def:getSeed soapenv:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/"/>
' </soapenv:Body>
' </soapenv:Envelope>
Dim xml As New ChilkatXml
xml.Tag = "soapenv:Envelope"
success = xml.AddAttribute("xmlns:xsi","http://www.w3.org/2001/XMLSchema-instance")
success = xml.AddAttribute("xmlns:xsd","http://www.w3.org/2001/XMLSchema")
success = xml.AddAttribute("xmlns:soapenv","http://schemas.xmlsoap.org/soap/envelope/")
success = xml.AddAttribute("xmlns:def","http://DefaultNamespace")
xml.UpdateChildContent "soapenv:Header",""
success = xml.UpdateAttrAt("soapenv:Body|def:getSeed",1,"soapenv:encodingStyle","http://schemas.xmlsoap.org/soap/encoding/")
Dim resp As New ChilkatHttpResponse
success = http.HttpStr("POST",endPoint,xml.GetXml(),"utf-8","text/xml",resp)
If (success = 0) Then
Debug.Print http.LastErrorText
Exit Sub
End If
responseStatusCode = resp.StatusCode
Debug.Print "Response Status Code: " & responseStatusCode
' You may examine the exact HTTP header sent with the POST like this:
Debug.Print "LastHeader:"
Debug.Print http.LastHeader
' Examine the XML returned by the web service:
Debug.Print "XML Response:"
Dim xmlResp As New ChilkatXml
success = xmlResp.LoadXml(resp.BodyStr)
Debug.Print xmlResp.GetXml()
' Use this online tool to generate parsing code from response XML:
' Generate Parsing Code from XML
' The response is:
' <?xml version="1.0" encoding="UTF-8"?>
' <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
' <soapenv:Body>
' <ns1:getSeedResponse soapenv:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/" xmlns:ns1="http://DefaultNamespace">
' <ns1:getSeedReturn xsi:type="xsd:string"><?xml version="1.0" encoding="UTF-8"?><SII:RESPUESTA xmlns:SII="http://www.sii.cl/XMLSchema"><SII:RESP_BODY><SEMILLA>039159253918</SEMILLA></SII:RESP_BODY><SII:RESP_HDR><ESTADO>00</ESTADO></SII:RESP_HDR></SII:RESPUESTA></ns1:getSeedReturn>
' </ns1:getSeedResponse>
' </soapenv:Body>
' </soapenv:Envelope>
' Get the XML contained in the getSeedReturn element:
Dim embeddedXml As String
embeddedXml = xmlResp.GetChildContent("soapenv:Body|ns1:getSeedResponse|ns1:getSeedReturn")
Debug.Print embeddedXml
' The embedded XML is:
' <?xml version="1.0" encoding="UTF-8"?>
' <SII:RESPUESTA xmlns:SII="http://www.sii.cl/XMLSchema">
' <SII:RESP_BODY>
' <SEMILLA>039159397998</SEMILLA>
' </SII:RESP_BODY>
' <SII:RESP_HDR>
' <ESTADO>00</ESTADO>
' </SII:RESP_HDR>
' </SII:RESPUESTA>
' Get the seed:
Dim xml2 As New ChilkatXml
success = xml2.LoadXml(embeddedXml)
Dim seed As String
seed = xml2.GetChildContent("SII:RESP_BODY|SEMILLA")
Debug.Print "seed = " & seed
' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------