(Visual Basic 6.0) Duplicate openssl rsautl -encrypt –in mytext.txt -out mytest.enc -inkey mycertificate.cer -certin –pkcs

Demonstrates how to duplicate this OpenSSL command:

openssl.exe  rsautl -encrypt –in mytext.txt -out mytest.enc -inkey mycertificate.cer -certin –pkcs

Important: The RSA encryption algorithm produces different results for each call, even when encrypting the same data with the same key. Decryption however, will produce the correct results. This example demonstrates.

The reason this occurs is that RSA encryption uses PKCS1 v1.5 padding, and this padding scheme uses random bytes. It is random bytes in the padding that causes the result to be different each time.

The mytext.txt file is a small file. (RSA can only be used to encrypt or sign small amounts of data.)

How much data can be encrypted with "openssl rsautl"? The maximum size (in bytes) is the key size minus the overhead for the padding. The overhead size depends on the padding. With OAEP padding, the overhead is 42 bytes. With the default PKCSv1.5 padding, the overhead is 11 bytes.

Given a 2048-bit RSA key (256 bytes) and using PKCSv1.5 padding, the max data size that can be signed is 256 - 11 = 245 bytes.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim cert As New ChilkatCert

' Load the certificate from a file.
Dim success As Long
success = cert.LoadFromFile("mycertificate.cer")
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Load the file to be encrypted.
Dim bd As New ChilkatBinData
success = bd.LoadFile("mytext.txt")

Dim rsa As New ChilkatRsa

' Get the cert's public key.
Dim pubkey As PublicKey
Set pubkey = cert.ExportPublicKey()

' Import the public key into the RSA component:
success = rsa.ImportPublicKeyObj(pubkey)
If (success <> 1) Then

    Debug.Print rsa.LastErrorText
    Exit Sub
End If

' OpenSSL uses big-endian.
rsa.LittleEndian = 0

' Encrypt the contents of bd, replacing it with the encrypted data.
Dim bUsePrivateKey As Long
bUsePrivateKey = 0
success = rsa.EncryptBd(bd,bUsePrivateKey)
If (success <> 1) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

' Save the RSA encrypted data to a file.
success = bd.WriteFile("mytest.enc")
If (success <> 1) Then
    Debug.Print "Failed to write RSA encrypted output file."
    Exit Sub
End If

Debug.Print "Success."