Visual Basic 6.0

Encrypt with Chilkat, Decrypt with OpenSSL

See more OpenSSL Examples

Demonstrates how to RSA encrypt a string using Chilkat, and then shows the corresponding OpenSSL command to RSA decrypt. The OpenSSL command to decrypt is as follows:

openssl rsautl -decrypt -inkey VP_Private.pem -in rsa_encrypted.bin -out original.txt

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rsa As New ChilkatRsa

' Note: RSA encryption uses the public key.  
' RSA decryption uses the private key.
' The reason is that the public key can be freely provided to anybody.  This allows anybody
' to send an encrypted message to the private key owner, and only the private key owner 
' can decrypt.
Dim key As New PublicKey

' Load an RSA public key from a PEM file:
success = key.LoadFromFile("qa_data/pem/VP_Public.pem")
If (success = 0) Then
    Debug.Print key.LastErrorText
    Exit Sub
End If

' Load the public key into the RSA object.
success = rsa.UsePublicKey(key)
If (success = 0) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

Dim strToEncrypt As String
strToEncrypt = "00000000;XYZ2-3BHQ-ABCD-MMVV;6MY1-GHJK-9LRR;0"

' The LittleEndian property is 0 by default, but it is set here
' anyway to show that LittleEndian byte ordering is required for OpenSSL compatibility.
rsa.LittleEndian = 0

Dim usePrivateKey As Long
usePrivateKey = 0
Dim encryptedBytes() As Byte
encryptedBytes = rsa.EncryptString(strToEncrypt,usePrivateKey)
If (rsa.LastMethodSuccess = 0) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

' The OpenSSL command to decrypt would be this:
' openssl rsautl -decrypt -inkey VP_Private.pem -in rsa_encrypted.bin -out original.txt

Dim fac As New CkFileAccess
success = fac.WriteEntireFile("qa_output/rsa_encrypted.bin",encryptedBytes)
If (success = 0) Then
    Debug.Print fac.LastErrorText
    Exit Sub
End If

Debug.Print "RSA Encryption Succeeded."