(Visual Basic 6.0) Duplicate PHP's openssl_encrypt and openssl_random_pseudo_bytes

Demonstrates how to duplicate PHP's openssl_encrypt function. (https://www.php.net/manual/en/function.openssl-encrypt.php)

For more information, see https://www.php.net/manual/en/function.openssl-encrypt.php

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Duplicates thw following PHP script:

' $text = "This is a test";
' $passphrase = "my password";
' $iv = openssl_random_pseudo_bytes(openssl_cipher_iv_length("AES-256-CBC"));
' $crypted = base64_encode($iv.openssl_encrypt($text, "AES-256-CBC", $passphrase, OPENSSL_RAW_DATA, $iv));
' echo $crypted;

Dim success As Long
Dim crypt As New ChilkatCrypt2

Dim text As String
text = "This is a test"
Dim passphrase As String
passphrase = "my password"

' AES is a block cipher.  The IV size for any block cipher is the size of the block, which is defined by the encryption algorithm. 
' For AES, the block size is always 16 bytes, regardless of key size (i.e. 128-bits, 192-bits, or 256-bits).
' Therefore, generate 16 random bytes for the IV.
crypt.EncodingMode = "base64"
Dim ivBase64 As String
ivBase64 = crypt.GenRandomBytesENC(16)

Debug.Print "Generated IV = " & ivBase64

' Because we're doing AES-256-CBC, the key length must be 256-bits (i.e. 32 bytes).
' Given that our passphrase is a us-ascii string that can be shorter or longer than 32-bytes, we need to 
' somehow transform the passphrase to a 32-byte secret key.  We need to know what openssl_encrypt does.
' Here's the answer from the openssl_encrypt documentation:
' 
' "If the passphrase is shorter than expected, it is silently padded with NUL characters; 
' if the passphrase is longer than expected, it is silently truncated."

' OK.... so let's pad or shorten to get a 32-byte key.
Dim bdKey As New ChilkatBinData
success = bdKey.AppendString(passphrase,"utf-8")

Dim sz As Long
sz = bdKey.NumBytes
If (sz > 32) Then
    success = bdKey.RemoveChunk(32,sz - 32)
Else
    success = bdKey.Clear()
    success = bdKey.AppendPadded(passphrase,"utf-8",0,32)
End If

' Setup for encryption.
crypt.CryptAlgorithm = "aes"
crypt.KeyLength = 256
crypt.SetEncodedIV ivBase64,"base64"
crypt.SetEncodedKey bdKey.GetEncoded("base64"),"base64"

' Encrypt and base64 encode.
Dim cipherText64 As String
cipherText64 = crypt.EncryptStringENC(text)

' The PHP code fragment above returns the base64 encoded bytes of the IV and the encrypted text.
' So let's do that..
Dim bd As New ChilkatBinData
success = bd.AppendEncoded(ivBase64,"base64")
success = bd.AppendEncoded(cipherText64,"base64")
Dim result As String
result = bd.GetEncoded("base64")

Debug.Print "result = " & result

' Sample output:
' dN0vS1O0cWi5BbLAAY+NTf7bs3S27xzPf11RkG47sjs=

' Now let's decrypt from the output...

' Setup for decryption.
crypt.CryptAlgorithm = "aes"
crypt.KeyLength = 256
crypt.SetEncodedKey bdKey.GetEncoded("base64"),"base64"

Dim bdResult As New ChilkatBinData
success = bdResult.AppendEncoded(result,"base64")
crypt.SetEncodedIV bdResult.GetEncodedChunk(0,16,"base64"),"base64"

' Remove the IV (first 16 bytes) from the result.
success = bdResult.RemoveChunk(0,16)
success = crypt.DecryptBd(bdResult)
Dim originalText As String
originalText = bdResult.GetString("utf-8")

Debug.Print "original text = " & originalText