Visual Basic 6.0

Office365 POP3 Login with OAuth2 Authentication

See more Office365 Examples

Demonstrates how to authenticate using OAuth2 using the POP3 protocol with outlook.office365.com.

Note: This example requires Chilkat v9.5.0.83 or greater.

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim mailman As New ChilkatMailMan

mailman.MailHost = "outlook.office365.com"
mailman.MailPort = 995
mailman.PopSsl = 1

' Use your O365 email address here.
mailman.PopUsername = "OFFICE365_EMAIL_ADDRESS"

' When using OAuth2 authentication, leave the password empty.
mailman.PopPassword = ""

' Load our previously obtained OAuth2 access token.
Dim jsonToken As New ChilkatJsonObject
success = jsonToken.LoadFile("qa_data/tokens/office365.json")
If (success = 0) Then
    Debug.Print jsonToken.LastErrorText
    Exit Sub
End If

mailman.OAuth2AccessToken = jsonToken.StringOf("access_token")

' Make the TLS connection to the outlook.office365.com POP3 server.
success = mailman.Pop3Connect()
If (success <> 1) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

' Authenticate using XOAUTH2
success = mailman.Pop3Authenticate()
If (success <> 1) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

' Find out how many emails are on the server..
Dim numEmails As Long
numEmails = mailman.CheckMail()
If (numEmails < 0) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

' Examine the POP3 session log:
Debug.Print mailman.Pop3SessionLog

' The POP3 session log will look something like this:

' **** Connected to outlook.office365.com:995
' < +OK The Microsoft Exchange POP3 service is ready. [QwBIADIAUABSADEAOABD...YwBvAG0A]
' > AUTH XOAUTH2
' < + 
' > <base64 string in XOAUTH2 format>
' < +OK User successfully authenticated.
' > STAT
' < +OK 3 375302

' End the POP3 session and close the connection to the GMail server.
success = mailman.Pop3EndSession()
If (success <> 1) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

Debug.Print "Finished."