(Visual Basic 6.0) Office365 IMAP with Client Credentials

See more Office365 Examples

Demonstrates how to interact with the Office365 IMAP server using OAuth2 client credentials. This example uses a new feature available starting in Chilkat v9.5.0.97, which is to provide the client ID, client secret, and tenant ID to Chilkat, and internally Chilkat will fetch OAuth2 access token via client credentials as necessary. Therefore, it is no longer necessary for the application to explicitly fetch the OAuth2 access token beforehand.

Note: This requires the Azure Entra ID application to be configured for client credentials as detailed in this guide: Office365 App Setup for SMTP, POP, IMAP OAuth2 Client Credentials

Note: This example requires Chilkat v9.5.0.97 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Long

' ----------------------------------------------------------------------------------------
' Important:
' Your Azure Entra ID app must be explicitly setup to allow for the OAuth2 client credentials flow.
' Please follow the detailed guide for how to do it here:
' Office365 App Setup for SMTP, POP, IMAP OAuth2 Client Credentials
' 
' Note: Your registered App must have the SMTP.SendAsApp permission.
' ----------------------------------------------------------------------------------------

Dim json As New ChilkatJsonObject

' Use your App's actual client ID here:
success = json.UpdateString("client_id","2871da2c-8176-4b7f-869b-2311aa82e743")

' Use your App's actual client secret here:
success = json.UpdateString("client_secret","2hu9Q~r5QuryUcEkNbg1btLtnfU1VUXzhSCG6brH")

' Use this specific scope.
success = json.UpdateString("scope","https://outlook.office365.com/.default")

' Replace the tenant ID part of the URL with your tenant ID.
success = json.UpdateString("token_endpoint","https://login.microsoftonline.com/114d7ed6-71bf-4dbe-a866-748364121bf2/oauth2/v2.0/token")

Dim imap As New ChilkatImap

imap.Ssl = 1
imap.Port = 993

' Connect to the Office365 IMAP server.
success = imap.Connect("outlook.office365.com")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Use OAuth2 authentication.
imap.AuthMethod = "XOAUTH2"

' Here is where we use a new feature introduced in Chilkat v9.5.0.97
' Instead of providing a previously fetched OAuth2 access token, we instead provide the information (above)
' required for Chilkat to automatically fetch the access token via client credentials.
success = imap.Login("OFFICE365_EMAIL_ADDRESS",json.Emit())
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

Debug.Print "O365 IMAP OAuth2 authentication is successful."

' Do something...
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Your application can continue to do other things in the IMAP session....

' When finished, logout and close the connection.
success = imap.Logout()
success = imap.Disconnect()

Debug.Print "Finished."