(Visual Basic 6.0) Hungary NAV Token Exchange

Demonstrates the tokenExchange request for the Hungarian NAV Online Invoicing System REST API v2.0.

Note: This example requires Chilkat v9.5.0.83 or greater.

For more information, see https://onlineszamla.nav.gov.hu/api/files/container/download/Online%20Szamla_Interfesz%20specifik%C3%A1ci%C3%B3_EN_v2.0.pdf

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Build the following XML:

' Use this online tool to generate code from sample XML: 
' Generate Code to Create XML

' <?xml version="1.0" encoding="UTF-8"?>
' <TokenExchangeRequest xmlns="http://schemas.nav.gov.hu/OSA/2.0/api">
' 	<header>
' 		<requestId>RID896801578348</requestId>
' 		<timestamp>2019-09-11T10:55:31.440Z</timestamp>
' 		<requestVersion>2.0</requestVersion>
' 		<headerVersion>1.0</headerVersion>
' 	</header>
' 	<user>
' 		<login>lwilsmn0uqdxe6u</login>
' 		<passwordHash>2F43840A882CFDB7DB0FEC07D419D030D864B47B6B541DC280EF81B937B7A176E33C052B0D26638CC18A7A2C08D8D311733078A774BF43F6CA57FE8CD74DC28E</passwordHash>
' 		<taxNumber>11111111</taxNumber>
' 		<requestSignature>B4B5E0F197BFFD3DF69BCC98D3BE775F65FD5445EEF95C9D6B6C59425F2B81C4F6DA1FD563B0C7E7D98AF1E1725E5C63C2803B5D3A93D1C02ED354AC92F2CC94</requestSignature>
' 		<!--<signKey>ac-ac3a-7f661bff7d342N43CYX4U9FG</signKey>-->
' 	</user>
' 	<software>
' 		<softwareId>123456789123456789</softwareId>
' 		<softwareName>string</softwareName>
' 		<softwareOperation>LOCAL_SOFTWARE</softwareOperation>
' 		<softwareMainVersion>string</softwareMainVersion>
' 		<softwareDevName>string</softwareDevName>
' 		<softwareDevContact>string</softwareDevContact>
' 		<softwareDevCountryCode>HU</softwareDevCountryCode>
' 		<softwareDevTaxNumber>string</softwareDevTaxNumber>
' 	</software>
' </TokenExchangeRequest>

Dim success As Long
Dim crypt As New ChilkatCrypt2

Dim dtNow As New CkDateTime
success = dtNow.SetFromCurrentSystemTime()
Debug.Print dtNow.GetAsTimestamp(0)

' The hash algorithm for the password is SHA512 (not SHA3-512).
crypt.HashAlgorithm = "sha512"
crypt.EncodingMode = "hex"
Dim myPassword As String
myPassword = "my-password"
Dim passwordHash As String
passwordHash = crypt.HashStringENC(myPassword)

' Generate a random request ID like "RID215118906689"
Dim prng As New ChilkatPrng
Dim sbRequestId As New ChilkatStringBuilder
success = sbRequestId.Append("RID")
success = sbRequestId.Append(prng.RandomString(12,1,0,0))
Debug.Print "generated requestId = " & sbRequestId.GetAsString()

' Calculate the requestSignature
crypt.HashAlgorithm = "sha3-512"
Dim signatureKey As String
signatureKey = "ce-8f5e-215119fa7dd621DLMRHRLH2S"

Dim sbFinalHashBase As New ChilkatStringBuilder

' First append the timestamp because we are going to remove certain chars/parts.
success = sbFinalHashBase.Append(dtNow.GetAsTimestamp(0))
Dim numReplaced As Long
numReplaced = sbFinalHashBase.Replace("Z","")
numReplaced = sbFinalHashBase.Replace("-","")
numReplaced = sbFinalHashBase.Replace(":","")
numReplaced = sbFinalHashBase.Replace("T","")

' Prepend the requestId and append the signatureKey
success = sbFinalHashBase.Prepend(sbRequestId.GetAsString())
success = sbFinalHashBase.Append(signatureKey)

Dim requestSignature As String
requestSignature = crypt.HashStringENC(sbFinalHashBase.GetAsString())

Dim xml As New ChilkatXml
xml.Tag = "TokenExchangeRequest"
success = xml.AddAttribute("xmlns","http://schemas.nav.gov.hu/OSA/2.0/api")
xml.UpdateChildContent "header|requestId",sbRequestId.GetAsString()
xml.UpdateChildContent "header|timestamp",dtNow.GetAsTimestamp(0)
xml.UpdateChildContent "header|requestVersion","2.0"
xml.UpdateChildContent "header|headerVersion","1.0"
xml.UpdateChildContent "user|login","lwilsmn0uqdxe6u"
xml.UpdateChildContent "user|passwordHash",passwordHash
xml.UpdateChildContent "user|taxNumber","11111111"
xml.UpdateChildContent "user|requestSignature",requestSignature
xml.UpdateChildContent "software|softwareId","123456789123456789"
xml.UpdateChildContent "software|softwareName","string"
xml.UpdateChildContent "software|softwareOperation","LOCAL_SOFTWARE"
xml.UpdateChildContent "software|softwareMainVersion","string"
xml.UpdateChildContent "software|softwareDevName","string"
xml.UpdateChildContent "software|softwareDevContact","string"
xml.UpdateChildContent "software|softwareDevCountryCode","HU"
xml.UpdateChildContent "software|softwareDevTaxNumber","string"

' POST the XML to https://api-test.onlineszamla.nav.gov.hu/invoiceService/v2/tokenExchange
Dim http As New ChilkatHttp
http.Accept = "application/xml"
http.SetRequestHeader "Content-Type","application/xml"
Dim endpoint As String
endpoint = "https://api-test.onlineszamla.nav.gov.hu/invoiceService/v2/tokenExchange"
Dim resp As ChilkatHttpResponse
Set resp = http.PostXml(endpoint,xml.GetXml(),"utf-8")
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Debug.Print "Response status code = " & resp.StatusCode

Dim respXml As New ChilkatXml
success = respXml.LoadXml(resp.BodyStr)
Debug.Print "Response body:"
Debug.Print respXml.GetXml()

' Save our exchange token to a file to be used for subsequent requests.
success = respXml.SaveXml("qa_data/tokens/nav_exchange_token.xml")

' The result looks like this:

' <?xml version="1.0" encoding="UTF-8" standalone="yes"?>
' <TokenExchangeResponse xmlns="http://schemas.nav.gov.hu/OSA/2.0/api" xmlns:ns2="http://schemas.nav.gov.hu/OSA/2.0/data">
'     <header>
'         <requestId>RID789246611489</requestId>
'         <timestamp>2020-03-25T14:14:36Z</timestamp>
'         <requestVersion>2.0</requestVersion>
'         <headerVersion>1.0</headerVersion>
'     </header>
'     <result>
'         <funcCode>OK</funcCode>
'     </result>
'     <software>
'         <softwareId>123456789123456789</softwareId>
'         <softwareName>string</softwareName>
'         <softwareOperation>LOCAL_SOFTWARE</softwareOperation>
'         <softwareMainVersion>string</softwareMainVersion>
'         <softwareDevName>string</softwareDevName>
'         <softwareDevContact>string</softwareDevContact>
'         <softwareDevCountryCode>HU</softwareDevCountryCode>
'         <softwareDevTaxNumber>string</softwareDevTaxNumber>
'     </software>
'     <encodedExchangeToken>2lR5v57Tl ... 9n4tIWCYgjKQ==</encodedExchangeToken>
'     <tokenValidityFrom>2020-03-25T15:14:36.987+01:00</tokenValidityFrom>
'     <tokenValidityTo>2020-03-25T15:19:36.987+01:00</tokenValidityTo>
' </TokenExchangeResponse>

' Use this online tool to generate parsing code from sample XML: 
' Generate Parsing Code from XML

Dim TokenExchangeResponse_xmlns As String
TokenExchangeResponse_xmlns = respXml.GetAttrValue("xmlns")
Dim TokenExchangeResponse_xmlns_ns2 As String
TokenExchangeResponse_xmlns_ns2 = respXml.GetAttrValue("xmlns:ns2")
Dim requestId As String
requestId = respXml.GetChildContent("header|requestId")
Dim timestamp As String
timestamp = respXml.GetChildContent("header|timestamp")
Dim requestVersion As String
requestVersion = respXml.GetChildContent("header|requestVersion")
Dim headerVersion As String
headerVersion = respXml.GetChildContent("header|headerVersion")
Dim funcCode As String
funcCode = respXml.GetChildContent("result|funcCode")
Dim softwareId As String
softwareId = respXml.GetChildContent("software|softwareId")
Dim softwareName As String
softwareName = respXml.GetChildContent("software|softwareName")
Dim softwareOperation As String
softwareOperation = respXml.GetChildContent("software|softwareOperation")
Dim softwareMainVersion As String
softwareMainVersion = respXml.GetChildContent("software|softwareMainVersion")
Dim softwareDevName As String
softwareDevName = respXml.GetChildContent("software|softwareDevName")
Dim softwareDevContact As String
softwareDevContact = respXml.GetChildContent("software|softwareDevContact")
Dim softwareDevCountryCode As String
softwareDevCountryCode = respXml.GetChildContent("software|softwareDevCountryCode")
Dim softwareDevTaxNumber As String
softwareDevTaxNumber = respXml.GetChildContent("software|softwareDevTaxNumber")
Dim encodedExchangeToken As String
encodedExchangeToken = respXml.GetChildContent("encodedExchangeToken")
Dim tokenValidityFrom As String
tokenValidityFrom = respXml.GetChildContent("tokenValidityFrom")
Dim tokenValidityTo As String
tokenValidityTo = respXml.GetChildContent("tokenValidityTo")