(Visual Basic 6.0) Export a Private Key from an MS Storage Provider

Demonstrates how to export a private key from a Microsoft Storage Provider.

Note: This example requires Chilkat v9.5.0.83 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires Chilkat v9.5.0.83 or greater.

' We'll export a certificate's private key from the MS storage provider.
' It is assumed the certificate + private key is already installed on the Windows system.
' The export does not remove the key from the Windows storage provider.

' First, let's get a certificate in one of the many ways we can do it.
' (I ran certmgr.msc, opened a certificate, and noted it's thumbprint.)
Dim cert As New ChilkatCert
Dim success As Long
success = cert.LoadByThumbprint("ea5a129c1919a52d238ee28d9f3a8f345b768388","hex")
If (success = 0) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

Debug.Print "Found: " & cert.SubjectDN

' First export the private key the easy way.
Dim privKey As PrivateKey
Set privKey = cert.ExportPrivateKey()
If (cert.LastMethodSuccess = 0) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' OK.. we have the private key.  Do whatever we want with it..

' -------------------------------------------------------------
' Now let's export in a more roundabout way by getting information about the 
' storage provider and key name and then we'll export completely independent
' of the certificate.
' 
' Remember: The private key is not contained within the certificate.  An X.509 certificate
' embeds the public key, but the counterpart private key is stored elsewhere, such
' as in a .pfx/.p12, or as in this case, in the Windows "protected store", or perhaps on
' a smartcard or hardware token.  (But a private key stored on a smartcard or token cannot
' be exported.  It must remain on the hardware.)
' 

Dim storageProvider As String
storageProvider = cert.CspName
Dim keyName As String
keyName = cert.KeyContainerName

Debug.Print "Information about the certificate's private key:"
Debug.Print "Storage Provider: " & storageProvider
Debug.Print "Key Name: " & keyName

' Export using just the name of the storage provider and key.
Dim keyCon As New KeyContainer
Dim privKey2 As New PrivateKey
Dim silentFlag As Long
silentFlag = 0
success = keyCon.ExportKey(keyName,storageProvider,silentFlag,privKey2)
If (success = 0) Then
    Debug.Print keyCon.LastErrorText
    Exit Sub
End If

' OK.. we have the private key in privKey2.  Do whatever we want with it..
' Perhaps we save as encrypted PKCS8 PEM.
success = privKey2.SavePkcs8EncryptedPemFile("myPassword","qa_output/privKey2.pem")
If (success = 0) Then
    Debug.Print privKey2.LastErrorText
    Exit Sub
End If

Debug.Print "Success."