(Visual Basic 6.0) Parse Multipart Binary Http Response

This example demonstrates how to parse an HTTP response that is multipart and contains a binary file, such as a .zip or .pdf.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Long
Dim http As New ChilkatHttp

Dim req As New ChilkatHttpRequest

' ...
' Insert code here to construct some kind of HTTP request.
' this example is to show how to parse a particular kind of response.
' ...
' ...

' Send the request (whatever it may be in your case) to get the HTTP response object.
Dim resp As ChilkatHttpResponse
Set resp = http.SynchronousRequest("www.somedomain.com",443,1,req)
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' Get the response body (which is expected to be binary)
Dim respBody As New ChilkatBinData
success = resp.GetBodyBd(respBody)

' For this example, the response body contains something like this:

' ------=_Part_21302_2029949381.1547401515443
' Content-Type: application/xop+xml; charset=UTF-8; type="text/xml"
' Content-Transfer-Encoding: 8bit
' Content-ID: <rootpart@ws.jboss.org>
' 
' <env:Envelope xmlns:env='http://schemas.xmlsoap.org/soap/envelope/'><env:Header></env:Header><env:Body>...</env:Body></env:Envelope>
' ------=_Part_21302_2029949381.1547401515443
' Content-Type: application/octet-stream
' Content-Transfer-Encoding: binary
' Content-Id: <fileArchivio-7d302908-4d64-43d3-bf4e-79ce806d43b3@ws.jboss.org>
' 
' BINARY_CONTENT_HERE...
' 
' ------=_Part_21302_2029949381.1547401515443--
' 

' Load it into a Chilkat MIME object.
Dim mime As New ChilkatMime
success = mime.LoadMimeBd(respBody)
If (success <> 1) Then
    Debug.Print mime.LastErrorText
    Exit Sub
End If

Dim numParts As Long
numParts = mime.NumParts
If (numParts < 2) Then
    Debug.Print "Expected multipart MIME with at least 2 sub-parts."
    Exit Sub
End If

' Get the 1st sub-part, which is the XML.
Dim part0 As ChilkatMime
Set part0 = mime.GetPart(0)
' Should be OK because we checked NumParts above..
Dim xmlStr As String
xmlStr = part0.GetBodyDecoded()
Debug.Print xmlStr
Debug.Print "----"

' Save the 2nd part to a file.  (It is a .zip file in our test case..)
Dim part1 As ChilkatMime
Set part1 = mime.GetPart(1)
success = part1.SaveBody("qa_output/attachedZip.zip")

' Alternatively, we could extract the binary data to a BinData and use elsewhere..
Dim zipData As New ChilkatBinData
success = part1.GetBodyBd(zipData)
success = zipData.WriteFile("qa_output/attachedZip_again.zip")

Debug.Print "OK."