Visual Basic 6.0

Append Part to MIME

See more MIME Examples

Demonstrates the AppendPart method for adding sub-parts to MIME. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Create a text/plain part.
Dim ptMime As New ChilkatMime
success = ptMime.SetBodyFromPlainText("This is the plain text body")
Debug.Print ptMime.GetMime()
Debug.Print "****"

' The ptMime contains:
' ---------------------------------------
' 	Content-Type: text/plain
' 	Content-Transfer-Encoding: 7bit
' 
' 	This is the plain text body
' ---------------------------------------

' Start with an empty MIME object...
Dim topLevelMime As New ChilkatMime

' Initialize it to a multipart Content-Type.  We'll use multipart/mixed.
success = topLevelMime.NewMultipartMixed()

' Append the ptMime as a child.
success = topLevelMime.AppendPart(ptMime)
Debug.Print topLevelMime.GetMime()
Debug.Print "****"

' The topLevelMime contains:
' --------------------------
' 	Content-Type: multipart/mixed; boundary="------------010907090104040508040404"
' 
' 	--------------010907090104040508040404
' 	Content-Type: text/plain
' 	Content-Transfer-Encoding: 7bit
' 
' 	This is the plain text body
' 	--------------010907090104040508040404--
' 

' IMPORTANT: A copy of the MIME passed in AppendPart is appended.
' Therefore, in this case, changing ptMime does not change the text/plain sub-part in topLevelMime.
' For example:
ptMime.SetBody "this is the new plain text body."
' topLevelMime is unchanged.
Debug.Print topLevelMime.GetMime()
Debug.Print "****"

' To change the content in topLevelMime, we must get the text/plain part.
' For example:

Dim ptMime2 As New ChilkatMime
success = topLevelMime.PartAt(0,ptMime2)

ptMime2.SetBody "this is the new plain text body."
' Now topLevelMime is changed.
Debug.Print topLevelMime.GetMime()