Visual Basic 6.0

Get OAuth2 Access Token for Azure Registered App

Demonstrates how to get OAuth2 access token for an Azure Registered App from a desktop application or script. This example demonstrates the OAuth2 authorization flow.

This example requires Chilkat v10.1.2 or greater.

Visual Basic 6.0

Dim success As Long
success = 0

' To further clarify, see OAuth 2.0 Authorization Flow

Dim oauth2 As New ChilkatOAuth2

' This should be the port in the localhost callback URL for your app.  
' The callback URL would look like "http://localhost:3017/" if the port number is 3017.
oauth2.ListenPort = 3017

' ----------------------------------------------------------------------------------------------------------
' The screenshot at the bottom of this page shows how we created the Azure App Registration for this example.
' ----------------------------------------------------------------------------------------------------------

' Note: The endpoint depends on the Azure App Registration.
' See How to Choose the Correct Endpoints for your Azure App Registration
oauth2.AuthorizationEndpoint = "https://login.microsoftonline.com/common/oauth2/v2.0/authorize"
oauth2.TokenEndpoint = "https://login.microsoftonline.com/common/oauth2/v2.0/token"

' Replace these with actual values.
oauth2.ClientId = "CLIENT_ID"

' This is for Require Proof Key for Code Exchange (PKCE)
' See OAuth2 PKCE Explained
oauth2.CodeChallenge = 1
oauth2.CodeChallengeMethod = "S256"

' Provide a SPACE separated list of scopes.
' See https://developer.microsoft.com/en-us/graph/docs/authorization/permission_scopes 

' Important: To get a refresh token in the final response, ask for "offline_access" scope
oauth2.Scope = "openid profile offline_access user.readwrite mail.readwrite mail.send files.readwrite"

' Begin the OAuth2 three-legged flow.  This returns a URL that should be loaded in a browser.
Dim url As String
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> 1) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

' Launch the default browser on the system and navigate to the url.
' The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = 0) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

' Wait for the user to approve or deny authorization in the browser.
Dim numMsWaited As Long
numMsWaited = 0
Do While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Loop

' If the browser does not respond within the specified time, AuthFlowState will be:
' 
' 1: Waiting for Redirect � The OAuth2 background thread is waiting for the browser's redirect request.
' 2: Waiting for Final Response � The thread is awaiting the final access token response.
' In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    Debug.Print "No response from the browser!"
    Exit Sub
End If

' Check AuthFlowState to determine if authorization was granted, denied, or failed:
' 
' 3: Success � OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
' 4: Access Denied � OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
' 5: Failure � OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    Debug.Print "OAuth2 failed to complete."
    Debug.Print oauth2.FailureInfo
    Exit Sub
End If

If (oauth2.AuthFlowState = 4) Then
    Debug.Print "OAuth2 authorization was denied."
    Debug.Print oauth2.AccessTokenResponse
    Exit Sub
End If

If (oauth2.AuthFlowState <> 3) Then
    Debug.Print "Unexpected AuthFlowState:" & oauth2.AuthFlowState
    Exit Sub
End If

Debug.Print "OAuth2 authorization granted!"
Debug.Print "Access Token = " & oauth2.AccessToken

' When the token is near expiration, your app can refresh as shown here:
' Refresh Expiring OAuth2 Access Token for Azure Registered App

' Get the full JSON response:
Dim json As New ChilkatJsonObject
success = json.Load(oauth2.AccessTokenResponse)
json.EmitCompact = 0

' The JSON response looks like this:

' {
'   "token_type": "Bearer",
'   "scope": "User.Read Mail.ReadWrite Mail.Send",
'   "expires_in": 3600,
'   "ext_expires_in": 0,
'   "access_token": "EwBAA8l6B...",
'   "refresh_token": "MCRMdbe...",
'   "id_token": "eyJ0eXA..."
' }

' If an "expires_on" member does not exist, then add the JSON member by
' getting the current system date/time and adding the "expires_in" seconds.
' This way we'll know when the token expires.
If (json.HasMember("expires_on") <> 1) Then
    Dim dtExpire As New CkDateTime
    success = dtExpire.SetFromCurrentSystemTime()
    success = dtExpire.AddSeconds(json.IntOf("expires_in"))
    success = json.AppendString("expires_on",dtExpire.GetAsUnixTimeStr(0))
End If

Debug.Print json.Emit()

' Save the JSON to a file for future requests.
Dim fac As New CkFileAccess
success = fac.WriteEntireTextFile("qa_data/tokens/_myAzureApp.json",json.Emit(),"utf-8",0)

' This is a screenshot of how we created the Azure App for this example:
'