(Visual Basic 6.0) Create JWT Using RSA (RS256, RS384, or RS512)

Demonstrates how to create a JWT using an RSA private key. This is for JOSE headers with an "alg" of RS256, RS384, or RS512. When RSA is used, the private key signs (creates) the JWT, and the public key is for verification.

This example also demonstrates how to include time constraints:

• nbf: Not Before Time
• exp: Expiration Time
• iat: Issue At Time

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' Demonstrates how to create a JWT using an RSA private key.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim privKey As New PrivateKey

' Load an RSA private key from a PEM file.
Dim success As Long
success = privKey.LoadEncryptedPemFile("qa_data/pem/rsa_passwd.pem","passwd")
If (success <> 1) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

Dim jwt As New ChilkatJwt

' Build the JOSE header
Dim jose As New ChilkatJsonObject
' Use RS256.  Pass the string "RS384" or "RS512" to use RSA with SHA-384 or SHA-512.
success = jose.AppendString("alg","RS256")
success = jose.AppendString("typ","JWT")

' Now build the JWT claims (also known as the payload)
Dim claims As New ChilkatJsonObject
success = claims.AppendString("iss","http://example.org")
success = claims.AppendString("sub","John")
success = claims.AppendString("aud","http://example.com")

' Set the timestamp of when the JWT was created to now.
Dim curDateTime As Long
curDateTime = jwt.GenNumericDate(0)
success = claims.AddIntAt(-1,"iat",curDateTime)

' Set the "not process before" timestamp to now.
success = claims.AddIntAt(-1,"nbf",curDateTime)

' Set the timestamp defining an expiration time (end time) for the token
' to be now + 1 hour (3600 seconds)
success = claims.AddIntAt(-1,"exp",curDateTime + 3600)

' Produce the smallest possible JWT:
jwt.AutoCompact = 1

' Create the JWT token.  This is where the RSA signature is created.
Dim token As String
token = jwt.CreateJwtPk(jose.Emit(),claims.Emit(),privKey)

Debug.Print token