(Visual Basic 6.0) JWS Using RSASSA-PSS using SHA-256 and MGF1 with SHA-256

Creates and validates a JSON Web Signature (JWS) using RSASSA-PSS using SHA-256 and MGF1 with SHA-256.

Chilkat supports all of the following JWS algorithms:

   +--------------+-------------------------------+--------------------+
   | "alg" Param  | Digital Signature or MAC      | Implementation     |
   | Value        | Algorithm                     | Requirements       |
   +--------------+-------------------------------+--------------------+
   | HS256        | HMAC using SHA-256            | Required           |
   | HS384        | HMAC using SHA-384            | Optional           |
   | HS512        | HMAC using SHA-512            | Optional           |
   | RS256        | RSASSA-PKCS1-v1_5 using       | Recommended        |
   |              | SHA-256                       |                    |
   | RS384        | RSASSA-PKCS1-v1_5 using       | Optional           |
   |              | SHA-384                       |                    |
   | RS512        | RSASSA-PKCS1-v1_5 using       | Optional           |
   |              | SHA-512                       |                    |
   | ES256        | ECDSA using P-256 and SHA-256 | Recommended+       |
   | ES384        | ECDSA using P-384 and SHA-384 | Optional           |
   | ES512        | ECDSA using P-521 and SHA-512 | Optional           |
   | PS256        | RSASSA-PSS using SHA-256 and  | Optional           |
   |              | MGF1 with SHA-256             |                    |
   | PS384        | RSASSA-PSS using SHA-384 and  | Optional           |
   |              | MGF1 with SHA-384             |                    |
   | PS512        | RSASSA-PSS using SHA-512 and  | Optional           |
   |              | MGF1 with SHA-512             |                    |
   +--------------+-------------------------------+--------------------+

Note: This example requires Chilkat v9.5.0.66 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This example requires Chilkat v9.5.0.66 or greater.

' Use the following RSA key loaded from JWK format.
Dim sbJwk As New ChilkatStringBuilder
success = sbJwk.Append("{""kty"":""RSA"",")
success = sbJwk.Append("""n"":""ofgWCuLjybRlzo0tZWJjNiuSfb4p4fAkd_wWJcyQoTbji9k0l8W26mPddx")
success = sbJwk.Append("HmfHQp-Vaw-4qPCJrcS2mJPMEzP1Pt0Bm4d4QlL-yRT-SFd2lZS-pCgNMs")
success = sbJwk.Append("D1W_YpRPEwOWvG6b32690r2jZ47soMZo9wGzjb_7OMg0LOL-bSf63kpaSH")
success = sbJwk.Append("SXndS5z5rexMdbBYUsLA9e-KXBdQOS-UTo7WTBEMa2R2CapHg665xsmtdV")
success = sbJwk.Append("MTBQY4uDZlxvb3qCo5ZwKh9kG4LT6_I5IhlJH7aGhyxXFvUK-DWNmoudF8")
success = sbJwk.Append("NAco9_h9iaGNj8q2ethFkMLs91kzk2PAcDTW9gb54h4FRWyuXpoQ"",")
success = sbJwk.Append("""e"":""AQAB"",")
success = sbJwk.Append("""d"":""Eq5xpGnNCivDflJsRQBXHx1hdR1k6Ulwe2JZD50LpXyWPEAeP88vLNO97I")
success = sbJwk.Append("jlA7_GQ5sLKMgvfTeXZx9SE-7YwVol2NXOoAJe46sui395IW_GO-pWJ1O0")
success = sbJwk.Append("BkTGoVEn2bKVRUCgu-GjBVaYLU6f3l9kJfFNS3E0QbVdxzubSu3Mkqzjkn")
success = sbJwk.Append("439X0M_V51gfpRLI9JYanrC4D4qAdGcopV_0ZHHzQlBjudU2QvXt4ehNYT")
success = sbJwk.Append("CBr6XCLQUShb1juUO1ZdiYoFaFQT5Tw8bGUl_x_jTj3ccPDVZFD9pIuhLh")
success = sbJwk.Append("BOneufuBiB4cS98l2SR_RQyGWSeWjnczT0QU91p1DhOVRuOopznQ"",")
success = sbJwk.Append("""p"":""4BzEEOtIpmVdVEZNCqS7baC4crd0pqnRH_5IB3jw3bcxGn6QLvnEtfdUdi")
success = sbJwk.Append("YrqBdss1l58BQ3KhooKeQTa9AB0Hw_Py5PJdTJNPY8cQn7ouZ2KKDcmnPG")
success = sbJwk.Append("BY5t7yLc1QlQ5xHdwW1VhvKn-nXqhJTBgIPgtldC-KDV5z-y2XDwGUc"",")
success = sbJwk.Append("""q"":""uQPEfgmVtjL0Uyyx88GZFF1fOunH3-7cepKmtH4pxhtCoHqpWmT8YAmZxa")
success = sbJwk.Append("ewHgHAjLYsp1ZSe7zFYHj7C6ul7TjeLQeZD_YwD66t62wDmpe_HlB-TnBA")
success = sbJwk.Append("-njbglfIsRLtXlnDzQkv5dTltRJ11BKBBypeeF6689rjcJIDEz9RWdc"",")
success = sbJwk.Append("""dp"":""BwKfV3Akq5_MFZDFZCnW-wzl-CCo83WoZvnLQwCTeDv8uzluRSnm71I3Q")
success = sbJwk.Append("CLdhrqE2e9YkxvuxdBfpT_PI7Yz-FOKnu1R6HsJeDCjn12Sk3vmAktV2zb")
success = sbJwk.Append("34MCdy7cpdTh_YVr7tss2u6vneTwrA86rZtu5Mbr1C1XsmvkxHQAdYo0"",")
success = sbJwk.Append("""dq"":""h_96-mK1R_7glhsum81dZxjTnYynPbZpHziZjeeHcXYsXaaMwkOlODsWa")
success = sbJwk.Append("7I9xXDoRwbKgB719rrmI2oKr6N3Do9U0ajaHF-NKJnwgjMd2w9cjz3_-ky")
success = sbJwk.Append("NlxAr2v4IKhGNpmM5iIgOS1VZnOZ68m6_pbLBSp3nssTdlqvd0tIiTHU"",")
success = sbJwk.Append("""qi"":""IYd7DHOhrWvxkwPQsRM2tOgrjbcrfvtQJipd-DlcxyVuuM9sQLdgjVk2o")
success = sbJwk.Append("y26F0EmpScGLq2MowX7fhd_QJQ3ydy5cY7YIBi87w93IKLEdfnbJtoOPLU")
success = sbJwk.Append("W0ITrJReOgo1cq9SbsxYawBgfp_gh6A5603k2-ZQwVK0JKSHuLFkuQ3U""")
success = sbJwk.Append("}")

Dim rsaKey As New PrivateKey
' Note: This example loads the RSA key from JWK format.  Any format can be loaded
' into the private key object. (See the online reference documentation..)
Dim success As Long
success = rsaKey.LoadJwk(sbJwk.GetAsString())
If (success <> 1) Then
    Debug.Print rsaKey.LastErrorText
    Exit Sub
End If

' Create the JWS Protected Header
Dim jwsProtHdr As New ChilkatJsonObject
success = jwsProtHdr.AppendString("alg","PS256")

Dim jws As New ChilkatJws

' Set the protected header:
Dim signatureIndex As Long
signatureIndex = 0
success = jws.SetProtectedHeader(signatureIndex,jwsProtHdr)

' Set the RSA key:
success = jws.SetPrivateKey(signatureIndex,rsaKey)

' Set the payload.
Dim bIncludeBom As Long
bIncludeBom = 0
Dim payloadStr As String
payloadStr = "In our village, folks say God crumbles up the old moon into stars."
success = jws.SetPayload(payloadStr,"utf-8",bIncludeBom)

' Create the JWS
' By default, the compact serialization is used.
Dim jwsCompact As String
jwsCompact = jws.CreateJws()
If (jws.LastMethodSuccess <> 1) Then
    Debug.Print jws.LastErrorText
    Exit Sub
End If

Debug.Print "JWS: " & jwsCompact

' Note: RSA PSS padding uses random values, so the output will be different each time a signature is produced.
' sample output:
' JWS: eyJhbGciOiJQUzI1NiJ9.SW4gb3VyIHZpbGxhZ2UsIGZvbGtzIHNheSBHb2QgY3J1bWJsZXMgdXAgdGhlIG9sZCBtb29uIGludG8gc3RhcnMu.TRWhwRo5dMv9-8OzrInfJTwmUGYgjLfHk8lqF072ND-FmLWEBnUTOpY8oJXp8FdWw2SalbdOeNlrtlJjwk4XK8Ql2iJ_2qMCtxsvLPhKBOqFoAF4aBvTOEDVJDxf0DaBSiydEEtfTVV2iwBcjWabu5J2XieR5y7QZQtuHsn7T3qKBvCcCejN3Y2oqAT3qMHvu1fTms1r_91wBn_K7Wjd9UkZ1n02qQcUHJznR_OF2BgN7_KWIDAF9ZS9keoju2NPpPelO4yxa2XUPnehY3G7dHKoCxUEQR4d2Xc5voqDASTVCDqQS4PVOZdvT3Ein6-SanAlCwbWBbkvT8g6-5PImQ

' Now load the JWS, validate, and recover the original text.
Dim jws2 As New ChilkatJws

' Load the JWS.
success = jws2.LoadJws(jwsCompact)

Dim rsaPubKey As PublicKey
Set rsaPubKey = rsaKey.GetPublicKey()

' Set the RSA public key used for validation.
signatureIndex = 0
success = jws2.SetPublicKey(signatureIndex,rsaPubKey)

' Validate the 1st (and only) signature at index 0..
Dim v As Long
v = jws2.Validate(signatureIndex)
If (v < 0) Then
    ' Perhaps Chilkat was not unlocked or the trial expired..
    Debug.Print "Method call failed for some other reason."
    Debug.Print jws2.LastErrorText
    Exit Sub
End If

If (v = 0) Then
    Debug.Print "Invalid signature.  The RSA key was incorrect, the JWS was invalid, or both."
    Exit Sub
End If

' If we get here, the signature was validated..
Debug.Print "Signature validated."

' Recover the original content:
Debug.Print jws2.GetPayload("utf-8")

' Examine the protected header:
Dim joseHeader As ChilkatJsonObject
Set joseHeader = jws2.GetProtectedHeader(signatureIndex)
If (jws2.LastMethodSuccess <> 1) Then
    Debug.Print "No protected header found at the given index."
    Exit Sub
End If

joseHeader.EmitCompact = 0

Debug.Print "Protected (JOSE) header:"
Debug.Print joseHeader.Emit()

' Output:

' 	Signature validated.
' 	In our village, folks say God crumbles up the old moon into stars.
' 	Protected (JOSE) header:
' 	{ 
' 	  "alg": "PS256"
' 	}