(Visual Basic 6.0) Insert JSON Object into another JSON Object

Demonstrates how to insert one JSON object into another. Effectively, the JSON object must be copied into the other..

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' Imagine we have two separate JSON objects.
Dim jsonA As New ChilkatJsonObject
success = jsonA.UpdateString("animal","zebra")
success = jsonA.UpdateString("colors[0]","white")
success = jsonA.UpdateString("colors[1]","black")

jsonA.EmitCompact = 0
Debug.Print jsonA.Emit()

' jsonA contains:

' {
'   "animal": "zebra",
'   "colors": [
'     "white",
'     "black"
'   ]
' }

Dim jsonB As New ChilkatJsonObject
success = jsonB.UpdateString("type","mammal")
success = jsonB.UpdateBool("carnivore",0)

jsonB.EmitCompact = 0
Debug.Print jsonB.Emit()

' jsonB contains:

' {
'   "type": "mammal",
'   "carnivore": false
' }

' Let's say we want to insert jsonB into jsonA to get this:

' {
'   "animal": "zebra",
'   "info" " {
'       "type": "mammal",
'       "carnivore": false
' 	},
'   "colors": [
'     "white",
'     "black"
'   ]
' }

' First add an empty object at the desired location:
success = jsonA.AddObjectAt(1,"info")

' Get the JSON object at that location, and load the JSON..
Dim jsonInfo As ChilkatJsonObject
Set jsonInfo = jsonA.ObjectOf("info")
success = jsonInfo.Load(jsonB.Emit())

Debug.Print jsonA.Emit()

' The end result is this:

' {
'   "animal": "zebra",
'   "info": {
'     "type": "mammal",
'     "carnivore": false
'   },
'   "colors": [
'     "white",
'     "black"
'   ]
' }