Visual Basic 6.0 Requires Chilkat v11.0.0+

Load Java KeyStore and Access Contents

See more Java KeyStore (JKS) Examples

Loads a Java keystore file and iterates over the contents. A Java keystore (.jks) file can contain one or more trusted root certificate entries and/or one or more private key entries. Each private key entry includes an associated certificate chain. Visual Basic 6.0

Dim success As Long
success = 0

'  This requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

Dim jks As New ChilkatJavaKeyStore

'  Load the Java keystore from a file.  The JKS file password is used
'  to verify the keyed digest that is found at the very end of the keystore.
'  It verifies there has been no tampering with the file.
success = jks.LoadFile("jksFilePassword","/someDir/keyStore.jks")
If (success = 0) Then
    Debug.Print jks.LastErrorText
    Exit Sub
End If

'  Find out how many of each type of entry:
Dim numTrustedCerts As Long
numTrustedCerts = jks.NumTrustedCerts
Dim numPrivateKeys As Long
numPrivateKeys = jks.NumPrivateKeys

Dim cert As New ChilkatCert
Dim alias As String

'  For each trusted certificate, access it by getting
'  it as a cert object.  Also get the alias associated with the certificate.
Debug.Print "Trusted Certs:"
Dim i As Long
i = 0
Do While i < numTrustedCerts
    success = jks.TrustedCertAt(i,cert)
    Debug.Print jks.GetTrustedCertAlias(i) & ": " & cert.SubjectDN
    i = i + 1
Loop

Dim privKey As New PrivateKey
Dim certChain As New ChilkatCertChain

'  For each private key entry, get the private key and
'  the associated certificate chain.
'  Each private key is password protected.  Usually it is the same
'  password as used for the keyed digest of the entire JKS.  
'  However, this does not have to be.  The password is passed
'  here to handle the possibility of each private key requiring
'  a different password.
Debug.Print "Private Keys:"
i = 0
Do While i < numPrivateKeys
    success = jks.PrivateKeyAt("jksFilePassword",i,privKey)
    Debug.Print jks.GetPrivateKeyAlias(i)
    success = jks.CertChainAt(i,certChain)

    '  The 1st certificate in the chain is the one associated with the private key.
    success = certChain.CertAt(0,cert)
    Debug.Print cert.SubjectDN

    i = i + 1
Loop