(Visual Basic 6.0) Add Private Key to Java Keystore

Adds a private key to an existing Java keystore.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim jks As New ChilkatJavaKeyStore

Dim jksPassword As String
jksPassword = "myJksPassword"
Dim jksPath As String
jksPath = "/someDir/keyStore.jks"

' Load the Java keystore from a file.
Dim success As Long
success = jks.LoadFile(jksPassword,jksPath)
If (success <> 1) Then
    Debug.Print jks.LastErrorText
    Exit Sub
End If

' A JKS private key entry consists of both the private key,
' it's associated certificate (which contains the matching public key
' within the X.509 of the certificate), and the certificates in the
' chain of authentication to the root.
' 
' Therefore, to add a private key entry to a JKS requires
' a Chilkat certificate object that has a private key and which also
' has the certificate chain (up to the root) available.

' There are many ways to get a Chilkat certificate object
' that contains (within it) the private key and the certificate chain
' This example will show two possibilities:
' (1) Where the cert and issuing root are provided in PEM format in .crt files,
' and the private key is also provided in unencrypted PEM format (.key file).
' (2) Where the cert, private key, and issuing root are provided in a single PFX.

' First for the .crt / .key files:
Dim cert As New ChilkatCert

' Chilkat will automatically determine the format of the cert file and load it correctly.
success = cert.LoadFromFile("/mycerts/alice.crt")
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Certificates required for building the chain of authentication can be
' added to an XML certificate vault object, and then provided as
' a source for obtaining certs when building the chain.
Dim certVault As New ChilkatXmlCertVault
success = certVault.AddCertFile("/mycerts/ca.crt")
If (success <> 1) Then
    Debug.Print certVault.LastErrorText
    Exit Sub
End If

success = cert.UseCertVault(certVault)
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Now provide the associated private key to the certificate object.
' The Chilkat private key class provides methods for loading from many formats (both
' encrypted and unencrypted).
Dim privKey As New PrivateKey
success = privKey.LoadPemFile("/mycerts/alice.key")
If (success <> 1) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

' Provide the certificate object with the private key:
success = cert.SetPrivateKey(privKey)
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Our certificate object now contains all that we need to add it as a private key entry
' to the Java keystore:
Dim alias As String
alias = "alice"
success = jks.AddPrivateKey(cert,alias,jksPassword)
If (success <> 1) Then
    Debug.Print jks.LastErrorText
    Exit Sub
End If

' Write the updated JKS, which contains the new private key entry w/ certificate chain.
success = jks.ToFile(jksPassword,jksPath)
If (success <> 1) Then
    Debug.Print jks.LastErrorText
    Exit Sub
End If

Debug.Print "Added new private key entry (from .crt and .key files) to the JKS!"

' Now let's add a new private key entry from a PFX that contains a single
' private key with associated cert and cert chain.
Dim pfx As New ChilkatPfx

success = pfx.LoadPfxFile("/myPfxFiles/my.pfx","pfxPassword")
If (success <> 1) Then
    Debug.Print pfx.LastErrorText
    Exit Sub
End If

' This is easy -- simply add the PFX to the JKS
alias = "bob"
success = jks.AddPfx(pfx,alias,jksPassword)
If (success <> 1) Then
    Debug.Print jks.LastErrorText
    Exit Sub
End If

' Write the updated JKS, which contains the new private key entry w/ certificate chain
' that came from the PFX.
success = jks.ToFile(jksPassword,jksPath)
If (success <> 1) Then
    Debug.Print jks.LastErrorText
    Exit Sub
End If

Debug.Print "Added new private key entry (from PFX) to the JKS!"