(Visual Basic 6.0) Create ITIDA Signed JSON and Send to ETA (Egypt Tax Authority) Portal

See more Egypt ITIDA Examples

Demonstrates how to create a .p7s signature that fits Egypt's ITIDA requirements where Chilkat automatically does the ITIDA JSON canonicalization. Also shows the code to send to the ETA Portal.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Indicate that utf-8 is desired for strings passed in and out of Chilkat.
Dim glob As New ChilkatGlobal
glob.DefaultUtf8 = 1

Dim crypt As New ChilkatCrypt2
crypt.VerboseLogging = 1

Dim cert As New ChilkatCert
cert.VerboseLogging = 1

' Set the smart card PIN, which will be needed for signing.
cert.SmartCardPin = "12345678"

' There are many ways to load the certificate.  
' This example was created for a customer using an ePass2003 USB token.
' Assuming the USB token is the only source of a hardware-based private key..
Dim success As Long
success = cert.LoadFromSmartcard("")
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Tell the crypt class to use this cert.
success = crypt.SetSigningCert(cert)
If (success <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Dim cmsOptions As New ChilkatJsonObject
' Setting "DigestData" causes OID 1.2.840.113549.1.7.5 (digestData) to be used.
success = cmsOptions.UpdateBool("DigestData",1)
success = cmsOptions.UpdateBool("OmitAlgorithmIdNull",1)

' Indicate that we are passing normal JSON and we want Chilkat do automatically
' do the ITIDA JSON canonicalization:
success = cmsOptions.UpdateBool("CanonicalizeITIDA",1)

crypt.CmsOptions = cmsOptions.Emit()

' The CadesEnabled property applies to all methods that create CMS/PKCS7 signatures. 
' To create a CAdES-BES signature, set this property equal to true. 
crypt.CadesEnabled = 1

crypt.HashAlgorithm = "sha256"

Dim jsonSigningAttrs As New ChilkatJsonObject
success = jsonSigningAttrs.UpdateInt("contentType",1)
success = jsonSigningAttrs.UpdateInt("signingTime",1)
success = jsonSigningAttrs.UpdateInt("messageDigest",1)
success = jsonSigningAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = jsonSigningAttrs.Emit()

' By default, all the certs in the chain of authentication are included in the signature.
' If desired, we can choose to only include the signing certificate:
crypt.IncludeCertChain = 0

' Pass a JSON document such as the following.  Chilkat will do the ITIDA canonicalization.
' (It is the canonicalized JSON that gets signed.)

'       {
'          "issuer":{
'             "address":{
'                "branchID":"0",
'                "country":"EG",
'                "regionCity":"Cairo",
'                "postalCode":"",
'                "buildingNumber":"0",
'                "street":"123rd Street",
'                "governate":"GOVERNATE"
'             },
'             "type":"B",
'             "id":"209999899",
'             "name":"Xyz SAE"
'          },
'          "receiver":{
'             "address":{
'                "country":"EG",
'                "regionCity":"CAIRO",
'                "postalCode":"11435",
'                "buildingNumber":"0",
'                "street":"Autostrad Road Abc",
'                "governate":"GOVERNATE"
'             },
'             "type":"B",
'             "id":"999999999",
'             "name":"XYZ EGYPT FOR TRADE"
'          },
'          "documentType":"I",
'          "documentTypeVersion":"1.0",
'          "dateTimeIssued":"2020-11-15T11:04:53Z",
'          "taxpayerActivityCode":"1073",
'          "internalID":"ZZZZ999",
'          "purchaseOrderReference":"2009199918",
'          "salesOrderReference":"",
'          "payment":{
'             "bankName":"",
'             "bankAddress":"",
'             "bankAccountNo":"",
'             "bankAccountIBAN":"",
'             "swiftCode":"",
'             "terms":""
'          },
'          "delivery":{
'             "approach":"",
'             "packaging":"",
'             "dateValidity":"",
'             "exportPort":"",
'             "countryOfOrigin":"EG",
'             "grossWeight":0,
'             "netWeight":0,
'             "terms":""
'          },
'          "invoiceLines":[
'             {
'                "description":"CDM Widget 48GX99X12BA",
'                "itemType":"GS1",
'                "itemCode":"7622213335056",
'                "unitType":"CS",
'                "quantity":1.00,
'                "unitValue":{
'                   "currencySold":"EGP",
'                   "amountEGP":588.67,
'                   "amountSold":0,
'                   "currencyExchangeRate":0
'                },
'                "salesTotal":588.67,
'                "total":603.97,
'                "valueDifference":0,
'                "totalTaxableFees":0,
'                "netTotal":529.8,
'                "itemsDiscount":0,
'                "discount":{
'                   "rate":10.00,
'                   "amount":58.87
'                },
'                "taxableItems":[
'                   {
'                      "taxType":"T1",
'                      "amount":74.17,
'                      "subType":"No sub",
'                      "rate":14.00
'                   }
'                ],
'                "internalCode":"9099994"
'             }
'          ],
'          "totalSales":588.67,
'          "totalSalesAmount":588.67,
'          "totalDiscountAmount":58.87,
'          "netAmount":529.80,
'          "taxTotals":[
'             {
'                "taxType":"T1",
'                "amount":74.17
'             }
'          ],
'          "extraDiscountAmount":0,
'          "totalItemsDiscountAmount":0,
'          "totalAmount":603.97,
'       }

' Build the above JSON..

' Use this online tool to generate code from sample JSON: 
' Generate Code to Create JSON

Dim json As New ChilkatJsonObject
success = json.UpdateString("issuer.address.branchID","0")
success = json.UpdateString("issuer.address.country","EG")
success = json.UpdateString("issuer.address.regionCity","Cairo")
success = json.UpdateString("issuer.address.postalCode","")
success = json.UpdateString("issuer.address.buildingNumber","0")
success = json.UpdateString("issuer.address.street","123rd Street")
success = json.UpdateString("issuer.address.governate","GOVERNATE")
success = json.UpdateString("issuer.type","B")
success = json.UpdateString("issuer.id","209999899")
success = json.UpdateString("issuer.name","Xyz SAE")
success = json.UpdateString("receiver.address.country","EG")
success = json.UpdateString("receiver.address.regionCity","CAIRO")
success = json.UpdateString("receiver.address.postalCode","11435")
success = json.UpdateString("receiver.address.buildingNumber","0")
success = json.UpdateString("receiver.address.street","Autostrad Road Abc")
success = json.UpdateString("receiver.address.governate","GOVERNATE")
success = json.UpdateString("receiver.type","B")
success = json.UpdateString("receiver.id","999999999")
success = json.UpdateString("receiver.name","XYZ EGYPT FOR TRADE")
success = json.UpdateString("documentType","I")
success = json.UpdateString("documentTypeVersion","1.0")
success = json.UpdateString("dateTimeIssued","2020-11-15T11:04:53Z")
success = json.UpdateString("taxpayerActivityCode","1073")
success = json.UpdateString("internalID","ZZZZ999")
success = json.UpdateString("purchaseOrderReference","2009199918")
success = json.UpdateString("salesOrderReference","")
success = json.UpdateString("payment.bankName","")
success = json.UpdateString("payment.bankAddress","")
success = json.UpdateString("payment.bankAccountNo","")
success = json.UpdateString("payment.bankAccountIBAN","")
success = json.UpdateString("payment.swiftCode","")
success = json.UpdateString("payment.terms","")
success = json.UpdateString("delivery.approach","")
success = json.UpdateString("delivery.packaging","")
success = json.UpdateString("delivery.dateValidity","")
success = json.UpdateString("delivery.exportPort","")
success = json.UpdateString("delivery.countryOfOrigin","EG")
success = json.UpdateInt("delivery.grossWeight",0)
success = json.UpdateInt("delivery.netWeight",0)
success = json.UpdateString("delivery.terms","")
success = json.UpdateString("invoiceLines[0].description","CDM Widget 48GX99X12BA")
success = json.UpdateString("invoiceLines[0].itemType","GS1")
success = json.UpdateString("invoiceLines[0].itemCode","7622213335056")
success = json.UpdateString("invoiceLines[0].unitType","CS")
success = json.UpdateNumber("invoiceLines[0].quantity","1.00")
success = json.UpdateString("invoiceLines[0].unitValue.currencySold","EGP")
success = json.UpdateNumber("invoiceLines[0].unitValue.amountEGP","588.67")
success = json.UpdateInt("invoiceLines[0].unitValue.amountSold",0)
success = json.UpdateInt("invoiceLines[0].unitValue.currencyExchangeRate",0)
success = json.UpdateNumber("invoiceLines[0].salesTotal","588.67")
success = json.UpdateNumber("invoiceLines[0].total","603.97")
success = json.UpdateInt("invoiceLines[0].valueDifference",0)
success = json.UpdateInt("invoiceLines[0].totalTaxableFees",0)
success = json.UpdateNumber("invoiceLines[0].netTotal","529.8")
success = json.UpdateInt("invoiceLines[0].itemsDiscount",0)
success = json.UpdateNumber("invoiceLines[0].discount.rate","10.00")
success = json.UpdateNumber("invoiceLines[0].discount.amount","58.87")
success = json.UpdateString("invoiceLines[0].taxableItems[0].taxType","T1")
success = json.UpdateNumber("invoiceLines[0].taxableItems[0].amount","74.17")
success = json.UpdateString("invoiceLines[0].taxableItems[0].subType","No sub")
success = json.UpdateNumber("invoiceLines[0].taxableItems[0].rate","14.00")
success = json.UpdateString("invoiceLines[0].internalCode","9099994")
success = json.UpdateNumber("totalSales","588.67")
success = json.UpdateNumber("totalSalesAmount","588.67")
success = json.UpdateNumber("totalDiscountAmount","58.87")
success = json.UpdateNumber("netAmount","529.80")
success = json.UpdateString("taxTotals[0].taxType","T1")
success = json.UpdateNumber("taxTotals[0].amount","74.17")
success = json.UpdateInt("extraDiscountAmount",0)
success = json.UpdateInt("totalItemsDiscountAmount",0)
success = json.UpdateNumber("totalAmount","603.97")

json.EmitCompact = 1
Dim jsonToSign As String
jsonToSign = json.Emit()

' Create the CAdES-BES signature.
crypt.EncodingMode = "base64"

' Make sure we sign the utf-8 byte representation of the JSON string
crypt.Charset = "utf-8"

Dim sigBase64 As String
sigBase64 = crypt.SignStringENC(jsonToSign)
If (crypt.LastMethodSuccess = 0) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Debug.Print "Base64 signature:"
Debug.Print sigBase64

' Insert the base64 signature into the JSON to be sent
success = json.UpdateString("signatures[0].signatureType","I")
success = json.UpdateString("signatures[0].value",sigBase64)

' Wrap the JSON in  {"documents":[ ... ]}
Dim sbToSend As New ChilkatStringBuilder
success = sbToSend.Append("{""documents"":[")
success = sbToSend.Append(json.Emit())
success = sbToSend.Append("]}")

' ------------------------------------------------------------------------
' Get an access token using our client ID and client secret key
Dim clientId As String
clientId = "abc999ff-1234"
Dim clientSecretKey As String
clientSecretKey = "123fff22-1234-abcd"

Dim http As New ChilkatHttp

' Causes the Authorization: Basic header to be added..
http.Login = clientId
http.Password = clientSecretKey
http.BasicAuth = 1

Dim req As New ChilkatHttpRequest
req.HttpVerb = "POST"
req.Path = "/connect/token"
req.ContentType = "application/x-www-form-urlencoded"
req.AddParam "grant_type","client_credentials"
req.AddHeader "Connection","close"

http.Accept = "application/json"

Dim resp As ChilkatHttpResponse
Set resp = http.PostUrlEncoded("https://id.preprod.eta.gov.eg/connect/token",req)
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

success = http.CloseAllConnections()

Debug.Print "Response status code: " & resp.StatusCode
Debug.Print "Response body:"
Debug.Print resp.BodyStr

If (resp.StatusCode <> 200) Then
    Debug.Print "Failed."

    Exit Sub
End If

Dim jsonToken As New ChilkatJsonObject
success = jsonToken.Load(resp.BodyStr)

Dim accessToken As String
accessToken = jsonToken.StringOf("access_token")
Debug.Print "access_token = " & accessToken

' ------------------------------------------------------------------------
' Submit the signed JSON to the ETA (Egypt Tax Authority) Portal

' No longer sending basic authentication...
http.Login = ""
http.Password = ""
http.BasicAuth = 0

' Setting the AuthToken property causes the "Authorization: Bearer <token>" header to be added to each request.
http.AuthToken = accessToken

Set resp = http.PostJson2("https://api.preprod.invoicing.eta.gov.eg/api/v1/documentsubmissions","application/json; charset=utf-8",sbToSend.GetAsString())
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Debug.Print "Response status code: " & resp.StatusCode
Debug.Print "Response body:"
Debug.Print resp.BodyStr