Visual Basic 6.0

Create Egypt ITIDA CAdES-BES .p7s Signature (with strings in-memory)

See more Egypt ITIDA Examples

Demonstrates how to create a .p7s signature that fits Egypt's ITIDA requirements.

Note: This example requires Chilkat v9.5.0.75 or greater.

Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As New ChilkatCrypt2

Dim cert As New ChilkatCert

' There are many ways to load the certificate.  
' This example was created for a customer using an ePass2003 USB token.
' Assuming the USB token is the only source of a hardware-based private key..
success = cert.LoadFromSmartcard("")
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Tell the crypt component to use this cert.
success = crypt.SetSigningCert(cert)
If (success <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Dim cmsOptions As New ChilkatJsonObject
' Setting "DigestData" causes OID 1.2.840.113549.1.7.5 (digestData) to be used.
success = cmsOptions.UpdateBool("DigestData",1)
success = cmsOptions.UpdateBool("OmitAlgorithmIdNull",1)
crypt.CmsOptions = cmsOptions.Emit()

' The CadesEnabled property applies to all methods that create CMS/PKCS7 signatures. 
' To create a CAdES-BES signature, set this property equal to true. 
crypt.CadesEnabled = 1

crypt.HashAlgorithm = "sha256"

Dim jsonSigningAttrs As New ChilkatJsonObject
success = jsonSigningAttrs.UpdateInt("contentType",1)
success = jsonSigningAttrs.UpdateInt("signingTime",1)
success = jsonSigningAttrs.UpdateInt("messageDigest",1)
success = jsonSigningAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = jsonSigningAttrs.Emit()

' By default, all the certs in the chain of authentication are included in the signature.
' If desired, we can choose to only include the signing certificate:
crypt.IncludeCertChain = 0

' Make sure we sign the utf-8 byte representation of the JSON string
crypt.Charset = "utf-8"

' Create the CAdES-BES signature.
Dim textToSign As String
textToSign = """issuer""""address""""branchID""""0""""country""""EG""""regionCity..."

crypt.EncodingMode = "base64"
Dim sigBase64 As String
sigBase64 = crypt.SignStringENC(textToSign)
If (crypt.LastMethodSuccess = 0) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Debug.Print "Base64 signature:"
Debug.Print sigBase64