Visual Basic 6.0

IMAP Read Encrypted Email

See more IMAP Examples

Demonstrates how to read encrypted email from an IMAP mailbox.

Reading encrypted email works the same as reading non-encrypted email. If the required certificate and private key are available on the system (e.g., in the macOS Keychain or Windows Certificate Store), Chilkat will automatically locate them, decrypt the email, and handle the process seamlessly.

Information about the original encrypted state of the email is available after it has been downloaded and decrypted.

Visual Basic 6.0

Dim success As Long
success = 0

Dim imap As New ChilkatImap

imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example2.com")
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' We'll get the IMAP email account's password from the Apple Keychain or Windows Credentials Manager.
' See how we originally saved the email credentials to the Keychain here:
' Save Email Credentials in Apple Keychain or Windows Credentials Manager
Dim secrets As New ChilkatSecrets

' On Windows, this is the Windows Credentials Manager
' On MacOS/iOS, it is the Apple Keychain
secrets.Location = "local_manager"

' Specify the name of the secret.
' service and username are required.
' appName and domain are optional.
' Note: The values are arbitrary and can be anything you want.
Dim json As New ChilkatJsonObject
success = json.UpdateString("appName","MyEmailApp")
success = json.UpdateString("service","IMAP")
success = json.UpdateString("domain","example2.com")
success = json.UpdateString("username","jane@example2.com")

Dim password As String
password = secrets.GetSecretStr(json)
If (secrets.LastMethodSuccess = 0) Then
    Debug.Print secrets.LastErrorText
    Exit Sub
End If

success = imap.Login("jane@example2.com",password)
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' This example: Send Encrypted Email using Certificate in Apple Keychain
' sent an email with the subject "This email is encrypted".
' Let's download an email with the word "encrypted" in the subject.

Dim messageSet As New MessageSet
success = imap.QueryMbx("SUBJECT encrypted",1,messageSet)
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

If (messageSet.Count = 0) Then
    Debug.Print "No messages found."
    Exit Sub
End If

' Reading encrypted email works the same as reading non-encrypted email. 
' If the required certificate and private key are available on the system (e.g., in the macOS Keychain or Windows Certificate Store), 
' Chilkat will automatically locate them, decrypt the email, and handle the process seamlessly.

Dim uid As Long
uid = messageSet.GetId(0)

Dim email As New ChilkatEmail
success = imap.FetchEmail(0,uid,1,email)
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Here we can show if the email was received encrypted, if it was successfully decrypted, and
' which certificate was used to decrypt.
Debug.Print "Email received encrypted: " & email.ReceivedEncrypted

' Was it successfully decrypted?
Debug.Print "Successfully decrypted: " & email.Decrypted

' What cert was used to decrypt?
Debug.Print "Encrypted by: " & email.EncryptedBy
Dim cert As New ChilkatCert
success = email.LastDecryptCert(cert)
If (success <> 0) Then
    Debug.Print "Certificate DN: " & cert.SubjectDN
End If

' Show the decrypted email body.
Debug.Print email.Body

success = imap.Disconnect()