(Visual Basic 6.0) Move Messages from one Mailbox to Another

If your IMAP server supports the MOVE capability, then it is possible to move messages from one mailbox (folder) to another. This example demonstrates the MOVE command using the SendRawCommand method. The IMAP MOVE Extension is documented in RFC 6851.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim imap As New ChilkatImap

' Use an implicit TLS connection.
imap.Ssl = 1
imap.Port = 993
Dim success As Long
success = imap.Connect("MY-IMAP-DOMAIN")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Authenticate
success = imap.Login("MY-IMAP-LOGIN","MY-IMAP-PASSWORD")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Get the list of capabilities:
Dim caps As String
caps = imap.Capability()
Debug.Print "Capabilities: " & caps

' Here is an example of the string returned:
' * CAPABILITY IMAP4rev1 UNSELECT IDLE NAMESPACE QUOTA ID XLIST CHILDREN X-GM-EXT-1 
' UIDPLUS COMPRESS=DEFLATE ENABLE MOVE CONDSTORE ESEARCH UTF8=ACCEPT APPENDLIMIT=35882577
' LIST-EXTENDED LIST-STATUS

If (imap.HasCapability("MOVE",caps) <> 1) Then
    Debug.Print "The IMAP server does not support the MOVE extension."
    Exit Sub
End If

Debug.Print "Good, the MOVE extension is supported..."

' Select a mailbox, search for some messages to get a sequence-set (i.e. a 
' range of message sequence numbers or UIDs.  Then move these messages to another
' mailbox.

success = imap.SelectMailbox("old")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Get a set of message sequence numbers for all emails with "Gencer" in the FROM name/address.
Dim bReturnUids As Long
bReturnUids = 0
Dim msgSet As MessageSet
Set msgSet = imap.Search("FROM Gencer",bReturnUids)
If (imap.LastMethodSuccess <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' The message set, as a compact string, will look something like this:
' 1572,1876:1881,1883,1886,1895,1905:1906,1910:1911,1923,1959:1963
Dim sequenceSet As String
sequenceSet = msgSet.ToCompactString()
Debug.Print sequenceSet

' Let's form our MOVE command.
Dim sbMoveCmd As New ChilkatStringBuilder
success = sbMoveCmd.Append("MOVE ")
success = sbMoveCmd.Append(sequenceSet)
success = sbMoveCmd.Append(" old/gencer")
Debug.Print "Sending: " & sbMoveCmd.GetAsString()

Dim cmdResponse As String
cmdResponse = imap.SendRawCommand(sbMoveCmd.GetAsString())
If (imap.LastMethodSuccess <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

Debug.Print cmdResponse

' The response looks like this:
' 	* 1572 EXPUNGE
' 	* 1875 EXPUNGE
' 	* 1875 EXPUNGE
' 	* 1875 EXPUNGE
' 	* 1875 EXPUNGE
' 	* 1875 EXPUNGE
' 	* 1875 EXPUNGE
' 	* 1876 EXPUNGE
' 	* 1878 EXPUNGE
' 	* 1886 EXPUNGE
' 	* 1895 EXPUNGE
' 	* 1895 EXPUNGE
' 	* 1898 EXPUNGE
' 	* 1898 EXPUNGE
' 	* 1909 EXPUNGE
' 	* 1944 EXPUNGE
' 	* 1944 EXPUNGE
' 	* 1944 EXPUNGE
' 	* 1944 EXPUNGE
' 	* 1944 EXPUNGE
' 	* 2274 EXISTS
' 	aaaf OK [COPYUID 62 1582,1886:1891,1893,1896,1905,1915:1916,1920:1921,1933,1974:1978 20,17,16,15,14,13,12,10:11,9,19,18,8,7,6,5,4,3,2,1] (Success)

' The last line should indicate OK.
' Note: Starting in Chilkat v9.5.0.62, the Chilkat will add a MoveMessages method to make this easier.
' Until then, or if using an older version of Chilkat, the response will need to be parsed for "OK" or "BAD".

' Disconnect from the IMAP server.
success = imap.Disconnect()

Debug.Print "All Done."