(Visual Basic 6.0) List IMAP Mailboxes

List the mailboxes available within an IMAP account.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim imap As New ChilkatImap

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
Dim success As Long
success = imap.Connect("MY-IMAP-DOMAIN")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Login
success = imap.Login("MY-IMAP-LOGIN","MY-IMAP-PASSWORD")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' The ListMailboxes method returns a Mailboxes object
' that contains the collection of mailboxes.
' It accepts two arguments: a refName and a wildcardedMailbox.

Dim refName As String
refName = ""
' refName is usually set to an empty string.
' A non-empty reference name argument is the name of a mailbox or a level of
' mailbox hierarchy, and indicates the context in which the mailbox
' name is interpreted.

' Select all mailboxes matching this pattern:
Dim wildcardedMailbox As String
wildcardedMailbox = "*"

Dim mboxes As Mailboxes
Set mboxes = imap.ListMailboxes(refName,wildcardedMailbox)
If (imap.LastMethodSuccess = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

Dim i As Long
i = 0
Do While i < mboxes.Count
    Debug.Print mboxes.GetName(i)
    i = i + 1
Loop

' Sample output looks like this:
' INBOX.vendors.shareit
' INBOX.oldSupport
' INBOX.vendors.paypal
' INBOX.sales
' INBOX.lists
' INBOX.Drafts
' INBOX.vendors.dell
' INBOX.Trash
' INBOX.invoiceRequests
' INBOX.purchases
' INBOX.vendors.inMotion
' INBOX.oldEmail
' INBOX.vendors
' INBOX.lists.python
' INBOX.vendors.myhosting
' INBOX.Templates
' INBOX.friends
' INBOX.bounceSamples
' INBOX.lists.ruby
' INBOX.vendors.peer1
' INBOX.Sent
' INBOX.Junk
' INBOX

' Disconnect from the IMAP server.
success = imap.Disconnect()