(Visual Basic 6.0) IMAP Get Quota Root

Sends the GETQUOTAROOT command to the IMAP server to get the quota root for a given mailbox. This also provides quota information for the given mailbox.

The GetQuotaRoot method is available in Chilkat starting at v9.5.0.58, and is only available for IMAP servers that support the QUOTA extension.

The information is returned in JSON format. This example demonstrates how to parse the JSON to get the desired information.

Typically, the quota root for the Inbox is the empty string.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim imap As New ChilkatImap

' Use TLS
imap.Ssl = 1
imap.Port = 993
Dim success As Long
success = imap.Connect("MY-IMAP-DOMAIN")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Authenticate
success = imap.Login("MY-IMAP-LOGIN","MY-IMAP-PASSWORD")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' First check to see if the IMAP server supports the QUOTA extension.
Dim caps As String
caps = imap.Capability()
If (imap.LastMethodSuccess <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

If (imap.HasCapability("QUOTA",caps) <> 1) Then
    Debug.Print "IMAP server does not support the QUOTA extension."
    Exit Sub
End If

Dim jsonStr As String
jsonStr = imap.GetQuotaRoot("Inbox")
If (imap.LastMethodSuccess <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' The JSON string will look something like this:
' {"QUOTAROOT":{"mailbox":"Inbox","root":""},"QUOTA":{"root":"","resource":"STORAGE","used":22216,"max":15728640}}
Debug.Print jsonStr

' This is easy to parse...
Dim json As New ChilkatJsonObject
success = json.Load(jsonStr)

' Get the quota root for Inbox, which is an empty string in the case above.
Dim quotaRoot As String
quotaRoot = json.StringOf("QUOTAROOT.root")
Debug.Print "Quota Root for Inbox: [" & quotaRoot & "]"

' Now get the resource name (which can be STORAGE or MESSAGE) and the used/max values.
' Most servers have STORAGE quotas, which are for total capacity.  For example, GMail's
' STORAGE quota is 15GB (at the time of writing this example).
' A MESSAGE quota sets a limit on the number of messages.
Dim resourceName As String
resourceName = json.StringOf("QUOTA.resource")
Dim quotaUsed As Long
quotaUsed = json.IntOf("QUOTA.used")
Dim quotaMax As Long
quotaMax = json.IntOf("QUOTA.max")

Debug.Print "Resource: " & resourceName
Debug.Print "Quota Used (in KB): " & quotaUsed
Debug.Print "Quota Max (in KB): " & quotaMax

' Disconnect from the IMAP server.
success = imap.Disconnect()