(Visual Basic 6.0) IMAP Get List of Flags

When a mailbox is selected, the server response includes a list of flags:

The FLAGS response occurs as a result of a SELECT or EXAMINE command. The flag parenthesized list identifies the flags (at a minimum, the system-defined flags) that are applicable for this mailbox. Flags other than the system flags can also exist, depending on server implementation.

This example demonstrates how to capture the SELECT (or EXAMINE) response, and parse the list of flags.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim imap As New ChilkatImap

' This example assumes Chilkat Imap to have been previously unlocked.
' See Unlock Imap for sample code.

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
Dim success As Long
success = imap.Connect("MY-IMAP-DOMAIN")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Login
success = imap.Login("MY-IMAP-LOGIN","MY-IMAP-PASSWORD")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("INBOX")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' The LastResponse property contains the full response of the last command.
Dim selectResponse As String
selectResponse = imap.LastResponse
Debug.Print selectResponse

' For example, on GMail, the SELECT response looks like this:

' 	* FLAGS (\Answered \Flagged \Draft \Deleted \Seen $Forwarded $NotPhishing $Phishing $label1 $label2 $label3 $label4 $label5 Junk NonJunk)
' 	* OK [PERMANENTFLAGS (\Answered \Flagged \Draft \Deleted \Seen $Forwarded $NotPhishing $Phishing $label1 $label2 $label3 $label4 $label5 Junk NonJunk \*)] Flags permitted.
' 	* OK [UIDVALIDITY 3] UIDs valid.
' 	* 46 EXISTS
' 	* 0 RECENT
' 	* OK [UIDNEXT 4147] Predicted next UID.
' 	* OK [HIGHESTMODSEQ 402971]
' 	aaac OK [READ-WRITE] INBOX selected. (Success)

' The goal of this example is to capture the list of FLAGS.
' All IMAP servers will respond with the list of flags in a SPACE separated list enclosed in parentheses.

Dim sbResponse As New ChilkatStringBuilder
success = sbResponse.Append(selectResponse)

' Get just the list of flags:
Dim sbFlagList As New ChilkatStringBuilder
success = sbFlagList.Append(sbResponse.GetAfterBetween("* FLAGS","(",")"))
Debug.Print sbFlagList.GetAsString()

' sbFlagList contains this:  
' 
'     \Answered \Flagged \Draft \Deleted \Seen $Forwarded $NotPhishing $Phishing $label1 $label2 $label3 $label4 $label5 Junk NonJunk
' 

' Make sure no more than one SPACE char in a row exists.
success = sbFlagList.TrimInsideSpaces()
' Modify sbFlagList to one flag per line
Dim numReplaced As Long
numReplaced = sbFlagList.Replace(" ",vbCrLf)

' Load a StringTable with the flag names.
Dim flagsTable As New ChilkatStringTable
success = flagsTable.AppendFromSb(sbFlagList)

' Iterate over the individual flag names:
Dim i As Long
i = 0
Do While i < flagsTable.Count
    Debug.Print i & ": " & flagsTable.StringAt(i)
    i = i + 1
Loop

' The output is:
' 
' 	0: \Answered
' 	1: \Flagged
' 	2: \Draft
' 	3: \Deleted
' 	4: \Seen
' 	5: $Forwarded
' 	6: $NotPhishing
' 	7: $Phishing
' 	8: $label1
' 	9: $label2
' 	10: $label3
' 	11: $label4
' 	12: $label5
' 	13: Junk
' 	14: NonJunk
'