Visual Basic 6.0

Fetch Inbox Email Headers

Downloads the headers of all emails in the Inbox and shows some information about each, such as From, Subject, and whether the email has been seen (already read) or not. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim imap As New ChilkatImap

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Login
success = imap.Login("myLogin","myPassword")
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Normally, when an email is downloaded, its "Seen" flag is automatically set.
' We don't want our program to be interfering with the "Seen" flags.
' To do this, set the PeekMode to 1.
imap.PeekMode = 1

' After selecting the mailbox, the NumMessages property
' will contain the number of emails in the mailbox.
' When sequence numbers (not UIDs) are used to reference emails,
' they range from 1 to N, where N is the number of messages in the mailbox.
' This example will download the headers by sequence numbers.
Dim count As Long
count = imap.NumMessages

Dim bundle As New ChilkatEmailBundle
success = imap.FetchRange(1,1,count,bundle)
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

If (bundle.MessageCount = 0) Then
    Debug.Print "No messages in Inbox."
    Exit Sub
End If

' Loop over the email headers.  
Dim emailHeader As New ChilkatEmail
Dim i As Long
i = 0
Do While i < bundle.MessageCount

    success = bundle.EmailAt(i,emailHeader)

    Debug.Print emailHeader.From
    Debug.Print emailHeader.Subject

    ' Get the "Seen" flag.
    ' When an email is fetched from the IMAP server, the email flags are stored
    ' within the email in the "ckx-imap-flags" header.
    ' The call to GetMailFlag is simply getting the information from the email header.
    ' (it is not communicating with the IMAP server to get this information, because
    ' the information was obtained when downloading the headers)
    Dim seenFlag As Long
    seenFlag = imap.GetMailFlag(emailHeader,"Seen")
    If (seenFlag = 1) Then
        Debug.Print "This email has been read (already seen)"
    Else
        Debug.Print "This email has not yet been read (it is not yet seen)"
    End If

    ' We can also look directly at the "ckx-imap-flags" header:
    Debug.Print "ckx-imap-flags: " & emailHeader.GetHeaderField("ckx-imap-flags")

    Debug.Print "--"

    i = i + 1
Loop

' Disconnect from the IMAP server.
success = imap.Disconnect()