Visual Basic 6.0

IMAP Download and Verify Signed (S/MIME) Email

See more IMAP Examples

Demonstrates how to download and verify digitally signed S/MIME email. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim imap As New ChilkatImap

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

success = imap.Login("myLogin","myPassword")
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' We can choose to fetch UIDs or sequence numbers.
Dim fetchUids As Long
fetchUids = 1

' Get the message IDs of all the emails in the mailbox
Dim messageSet As New MessageSet
success = imap.QueryMbx("ALL",fetchUids,messageSet)
If (success = 0) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

Dim email As New ChilkatEmail
Dim cert As New ChilkatCert

Dim i As Long
i = 0
Do While i < messageSet.Count

    Dim uid As String
    uid = messageSet.GetId(i)
    Debug.Print "uid: " & uid

    success = imap.FetchEmail(0,uid,1,email)
    If (success = 0) Then
        Debug.Print imap.LastErrorText
        Exit Sub
    End If

    ' The security layers of signed and/or encrypted emails
    ' are automatically "unwrapped" when loaded into
    ' a Chilkat email object.
    ' An application only needs to check to see if an email
    ' was received signed or encrypted, and then examine
    ' the success/failure.  For example:
    If (email.ReceivedSigned = 1) Then

        Debug.Print "This email was signed."

        ' Check to see if the signatures were verified.
        If (email.SignaturesValid = 1) Then
            Debug.Print "Digital signature(s) verified."
            Debug.Print "Signer: " & email.SignedBy

            ' Get the certificate used for signing.
            success = email.LastSignerCert(0,cert)

            If (success = 0) Then
                Debug.Print "Failed to get signing certificate object."
            Else
                Debug.Print "Signing cert: " & cert.SubjectCN
            End If

        Else
            Debug.Print "Digital signature verification failed."
        End If

    End If

    i = i + 1
Loop

' Disconnect from the IMAP server.
success = imap.Disconnect()