Visual Basic 6.0

Initialize an HTTP Request from a URL

See more HTTP Examples

Demonstrates how to initialize an HTTP request object from a URL. Visual Basic 6.0

Dim req As New ChilkatHttpRequest

' Loads the HTTP request object from a URL
req.SetFromUrl "https://www.youtube.com/watch?v=fAZdTchQePc&t=45s"

' The verb will be "GET"
Debug.Print "verb = " & req.HttpVerb
' The path will be "/watch"
Debug.Print "path = " & req.Path

' The output of this loop will be
' 0) v: fAZdTchQePc
' 1) t: 45s
Dim i As Long
Dim numParams As Long
numParams = req.NumParams
For i = 0 To numParams - 1
    Debug.Print i & ") " & req.GetParamName(i) & ": " & req.GetParamValue(i)
Next

' View the request that would be sent if HttpSReq is called.
' The HTTP request will be a GET that looks like this:
' 
'     GET /watch?v=fAZdTchQePc&t=45s HTTP/1.1
'     Host: domain
' 
' Note: The HOST header will automatically get filled in with the actual domain when HttpSReq is called.

Debug.Print req.GenerateRequestText()

' We can add additional params
req.AddParam "artist","Richard Bona"
req.AddParam "musicType","Jazz"
req.AddParam "festival","Estival Jazz Lugano"
req.AddParam "year","2008"

' Now examine the request that would be sent
' 
'     GET /watch?v=fAZdTchQePc&t=45s&artist=Richard%20Bona&musicType=Jazz&festival=Estival%20Jazz%20Lugano&year=2008 HTTP/1.1
'     Host: domain
' 
Debug.Print req.GenerateRequestText()

' We can remove a parameter:
req.RemoveParam "t"
Debug.Print req.GenerateRequestText()

' What happens if we change the request from a GET to a POST?
req.HttpVerb = "POST"
' The request will now look like this:
' 
'    POST /watch HTTP/1.1
'    Host: domain
'    Content-Length: 93
'    
'    v=fAZdTchQePc&artist=Richard%20Bona&musicType=Jazz&festival=Estival%20Jazz%20Lugano&year=2008
' 
Debug.Print req.GenerateRequestText()

' What happens if we make it a multipart/form-data?
req.ContentType = "multipart/form-data"
' Now the POST looks like this:
'    
'    POST /watch HTTP/1.1
'    Content-Type: multipart/form-data; boundary=------------020906020106050705030807
'    Host: domain
'    Content-Length: 545
'    
'    --------------020906020106050705030807
'    Content-Disposition: form-data; name="v"
'    
'    fAZdTchQePc
'    --------------020906020106050705030807
'    Content-Disposition: form-data; name="artist"
'    
'    Richard Bona
'    --------------020906020106050705030807
'    Content-Disposition: form-data; name="musicType"
'    
'    Jazz
'    --------------020906020106050705030807
'    Content-Disposition: form-data; name="festival"
'    
'    Estival Jazz Lugano
'    --------------020906020106050705030807
'    Content-Disposition: form-data; name="year"
'    
'    2008
'    --------------020906020106050705030807--

Debug.Print req.GenerateRequestText()