(Visual Basic 6.0) Creating an application/json HTTP POST Request

Demonstrates how to create an HTTP POST request having the Content-Type application/json, where the body of the HTTP request is the following JSON:

{
   "username" : "my_username",
   "password" : "my_password",
   "validation-factors" : {
      "validationFactors" : [
         {
            "name" : "remote_address",
            "value" : "127.0.0.1"
         }
      ]
   }
}

The generated HTTP request looks like this:

POST /something HTTP/1.1
Content-Type: application/json
Accept: application/json
Host: domain
Content-Length: 216

{
  "username": "my_username",
  "password": "my_password",
  "validation-factors": {
    "validationFactors": [
      {
        "name": "remote_address",
        "value": "127.0.0.1"
      }
    ]
  }
}

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example demonstrates building an application/json request.

Dim req As New ChilkatHttpRequest

' The ContentType, HttpVerb, and Path properties should
' always be explicitly set.
req.HttpVerb = "POST"
req.Path = "/something"
req.ContentType = "application/json"

' We may wish to add an "Accept" header to the request.
' This tells the server we'll accept an application/json response.
req.AddHeader "Accept","application/json"

' We'll use Chilkat's JSON API to create the JSON body of the HTTP request.
Dim json As New ChilkatJsonObject
success = json.AppendString("username","my_username")
success = json.AppendString("password","my_password")
Dim vFactors As ChilkatJsonObject
Set vFactors = json.AppendObject("validation-factors")
Dim vArray As ChilkatJsonArray
Set vArray = vFactors.AppendArray("validationFactors")
success = vArray.AddObjectAt(0)
Dim factorObj As ChilkatJsonObject
Set factorObj = vArray.ObjectAt(0)
success = factorObj.AppendString("name","remote_address")
success = factorObj.AppendString("value","127.0.0.1")

' Use the JSON for the HTTP request body
' By default, the Emit method will output compact JSON.
' This is best for generating the smallest size request.
' To generate a more human-readable (pretty-printed) JSON request body,
' set the EmitCompact property to FALSE
json.EmitCompact = 0
success = req.LoadBodyFromString(json.Emit(),"utf-8")

' View the request that would be sent if SynchronousRequest was called:
Dim requestMime As String
requestMime = req.GenerateRequestText()
Debug.Print requestMime

' A few important comments about the HTTP request that is generated:
' 
' 1) The Content-Length header is automatically generated based on the actual length of the MIME message
'    that follows the intial (topmost) MIME header.
' 2) The HOST header will automatically get filled in with the actual domain when SynchronousRequest
'    is called