(Visual Basic 6.0) QuickGetObj Example

The QuickGetObj method is called to send a GET request and receive the response as an HttpResponse object.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

' Send a GET request to download a PDF into an HTTP response object.
Dim resp As ChilkatHttpResponse
Set resp = http.QuickGetObj("https://www.chilkatsoft.com/hello.pdf")
If (http.LastMethodSuccess = 0) Then
    ' This will happen if the request could not be sent, or if no response was received.
    Debug.Print http.LastErrorText
    Exit Sub
End If

' Get the response status
Dim statusCode As Long
statusCode = resp.StatusCode
Debug.Print "Response status: " & statusCode

' In this example, we want a 200 status code.
If (statusCode = 200) Then
    ' Save the response body to a file.
    ' Note: This is only for the sake of this example.
    ' It's better to call the Download method to download directly to a file.
    Dim success As Long
    success = resp.SaveBodyBinary("qa_output/hello.pdf")
    If (success = 0) Then
        Debug.Print "Failed to write output file."
    Else
        Debug.Print "Wrote hello.pdf"
    End If

Else
    ' Perhaps we have response body with an error message..
    Debug.Print resp.BodyStr

End If